The session management exit routine initializes the output fields to a value of A70IMS for the LU name (RTNNAME1) and NET2 for the NETID (RTNNET1). However, if the first entry is not the DLU, or the LU name is not one of the NET2 application programs, the direction of session setup does not permit the alias function to provide an alias name; that is, a session initiated from the CICS or IMS application program requires the real name of the terminal. This sample session management exit routine cannot map an alias terminal that is pre-generated in IMS or CICS into a specific terminal name in the attached network (NET1). Therefore, this sample session management exit routine returns control to VTAM® and indicates that no translation is performed. The session setup proceeds assuming the correct names are supplied. The following sample code processes the first entry in the alias input parameter list:    

***********************************************************************
*        SME ROUTINE - ALIAS SELECTION
***********************************************************************
ALIAS    EQU   *
*
** LOCATE THE ALIAS PARAMETER LIST - INPUT AND OUTPUT ADDRESSES
*
ALIASS1  EQU   *
         L     R2,44(R11)       ALIAS INPUT PARAMETER LIST ADDRESS
         LA    R2,8(R2)    ALIAS FIRST LUNAME ADDRESS - REAL/ALIAS NAME
         L     R3,48(R11)       ALIAS OUTPUT PARAMETER LIST ADDRESS
*
** PROCESS FIRST LOGICAL UNIT NAME IN ALIAS INPUT PARAMETER LIST:
**
** IF FIRST ENTRY IS THE DLU AND NAME IS 'A50CICS', 'A60CICS',
** OR 'A70IMS' RETURN SAME NAME TO VTAM AND CHANGE THE NETID TO 'NET2',
** OTHERWISE, EXIT TO VTAM WITHOUT ALIAS TRANSLATION.
**
** REASONS: 1. TERMINAL INITIATED SESSION TO APPLICATION WHICH DOES NOT
**             REQUIRE ALIAS TRANSLATION.
**          2. APPLICATION INITIATED SESSION FOR WHICH SME EXIT CANNOT
**             MAP THE ALIAS NAME TO A REAL TERMINAL NAME
**          3. CDINIT-OTHER PROCESSING FOR WHICH SME EXIT DOES NOT
**             PROVIDE NECESSARY TRANSLATION.
*
ALIASS1A EQU   *
         TM    1(R2),X'20'       FIRST ENTRY - DLU NAME FOR
*                                CDINIT/DSRLST PROCESSING
         BNO   ALIASS2           NO, ALIAS TRANSLATION NOT PERFORMED
         CLC   8(8,R2),=CL8'A50CICS'  ALIAS NAME EQUAL A50CICS
*                                       APPLICATION
         BE    ALIASS1C          YES, RETURN SAME LUNAME AND NET2 NETID
         CLC   8(8,R2),=CL8'A60CICS'  ALIAS NAME EQUAL A60CICS
*                                       APPLICATION
         BE    ALIASS1C          YES, RETURN SAME LUNAME AND NET2 NETID
         CLC   8(8,R2),=CL8'A70IMS'   ALIAS NAME EQUAL A70IMS
*                                       APPLICATION
         BE    ALIASS1C          YES, RETURN SAME LUNAME AND NET2 NETID
ALIASS1B EQU   *
         LA    R15,0             NO TRANSLATION PERFORMED - NO ALIAS
*                                  APPLICATION
         B     RETURN            RETURN TO VTAM
ALIASS1C EQU   *
         MVC   0(8,R3),8(R2)     REAL DLU NAME EQUALS ALIAS APPLICATION
*                                  NAME
         MVC   48(8,R3),=CL8'NET2'  REAL NETID FOR DLU EQUALS NET2
         B     ALIASS2         CONTINUE PROCESSING, SECOND ALIAS ENTRY
***********************************************************************