Usage of QCMDEXC in ILE RPG IV program

     A                                      DSPSIZ(24 80 *DS3)
     A          R COMMANDREC                CA03(93)
     A                                 10  1'CL COMMAND: '
     A            COMMANDFLD    80A  B 12  1
     A                                 14  1'F3 = EXIT'       

**FREE
  // This program is a simple CL command interpreter.
  // The essential control flow consists of a loop, which prompts the user
  // for a CL command and then executes it.  The loop ends when the user
  // presses <F3>.
  // The code segment is intended to demonstrate the basic machinery involved
  // in using QCMDEXC in ILE RPG.
  //
  //
  // Externally described DSPF under user control.
  Dcl-F INTERPDSPF WORKSTN USROPN;
  //
  // Standalone field specifying the length of the command passed to QCMDEXC
  Dcl-S COMMANDLEN      Packed(15:5)    INZ(80);
  // Prototype for QCMDEXC
  Dcl-Pr Pgm_QCMDEXC ExtPgm('QCMDEXC');
    COMMANDFLD      Char(80);
    COMMANDLEN      Packed(15:5);
  End-Pr;
  //
  Open INTERPDSPF;
  //
  // Do until the user presses <F3>
  DoU *IN93 = *ON;
    //
    // Prompt user for a CL command and read response
    Exfmt COMMANDREC;
    //
    // Execute the command the user entered
    Pgm_QCMDEXC(COMMANDFLD : COMMANDLEN);
    //
    // Clear the DSPF record (clears out the last command the user keyed in)
    Clear COMMANDREC;
    //
    // Exit loop if user pressed <F3>
  EndDo;
  //
  Close INTERPDSPF;
  //
  *INLR = *ON;