How to know when iBase databases were accessed the last time (SQL Server format) ?

-- We get all the **_LOG SQL Databases and put them in a Cursor

-- For each one, we look in the table _AuditLog most recent record with Action_Type = 101
-- Action_Type = 101 corresponds to a user connecting to this iBase database from iBase (or ANB)
-- We then print this date, and we repeat for every *_LOG database

USE master;

DECLARE @DatabaseName NVarchar(300);
DECLARE @theSQL nvarchar(max);
DECLARE @LastAccessed nvarchar(50);
DECLARE @Result nvarchar(50);
DECLARE @OutputResults nvarchar(300);

-- We get all the ***_LOG SQL Databases and put them in a Cursor
DECLARE dbs CURSOR STATIC LOCAL FORWARD_ONLY READ_ONLY
FOR
SELECT name
FROM sys.databases
WHERE name like '%_LOG'
  AND state_desc = 'ONLINE';

OPEN dbs;
FETCH NEXT FROM dbs INTO @DatabaseName;

WHILE @@FETCH_STATUS = 0
BEGIN
    -- We check to see if the SQL Database is an iBase DB by searching for the _LinkEnd table
    IF OBJECT_ID (QUOTENAME(@DatabaseName) +'.dbo._AuditLog', N'U') IS NOT NULL
        BEGIN
            SET @OutputResults = LEFT(@DatabaseName, LEN(@DatabaseName) - 4)
            SET @theSQL = '    SELECT TOP 1 @LastAccessed = Date_Time
                FROM ' + QUOTENAME(@DatabaseName) + '.[dbo].[_AuditLog]  
                WHERE Action_Type = 101
                ORDER BY Date_Time DESC'

            EXEC sp_executesql @theSQL, N'@LastAccessed varchar(100) out', @Result out
            SET @OutputResults = @OutputResults + ' == Last Accessed : ' + LTRIM(@Result)

        -- And we print the result.
            RAISERROR(@OutputResults,0,1) WITH NOWAIT
        END;

   FETCH NEXT FROM dbs INTO @DatabaseName;
END
CLOSE dbs;
DEALLOCATE dbs;