Definition and Procedure Specification Name Field

The rules for continuation of the name on the definition and procedure specifications are:

• Continuation rules apply for names longer than 15 characters. Any name (even one with 15 characters or fewer) can be continued on multiple lines by coding an ellipsis (...) at the end of the partial name.
• A name definition consists of the following parts:
  1. Zero or more continued name lines. Continued name lines are identified as having an ellipsis as the last non-blank characters in the entry. The name must begin within positions 7 - 21 and may end anywhere up to position 77 (with an ellipsis ending in position 80). There cannot be blanks between the start of the name and the ellipsis (...) characters. If any of these conditions is not true, the line is considered to be a main definition line.
  2. One main definition line containing name, definition attributes, and keywords. If a continued name line is coded, the name entry of the main definition line may be left blank.
  3. Zero or more keyword continuation lines.

     Example

     *.. 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+... 7 ...+... 8
     DName++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
     DName+++++++++++ETDsFrom+++To/L+++IDc.Keywords+++++++++++++++++++++++++++++
     D                                     Keywords-cont++++++++++++++++++++++++
     * Long name without continued name lines:
     D RatherLongName  S             10A
     * Long name using 1 continued name line:
     D NameThatIsEvenLonger...
     D                 C                   'This is the constant -
     D                                     that the name represents.'
     * Long name using 1 continued name line:
     D NameThatIsSoLongItMustBe...
     D   Continued     S             10A
     * Compile-time arrays may have long names:
     D CompileTimeArrayContainingDataRepresentingTheNamesOfTheMonthsOf...
     D  TheYearInGermanLanguage...
     D                 S             20A   DIM(12) CTDATA PERRCD(1)
     * Long name using 3 continued name lines:
     D ThisNameIsSoMuchLongerThanThe...
     D    PreviousNamesThatItMustBe...
     D    ContinuedOnSeveralSpecs...
     D                 PR            10A
     D parm_1                        10A   VALUE
     *
     CL0N01Factor1+++++++Opcode(E)+Extended-factor2+++++++++++++++++++++++++++++
     C                             Extended-factor2-++++++++++++++++++++++++++++
     * Long names defined on calc spec:
     C     LongTagName   TAG
     C     *LIKE         DEFINE    RatherLongNameQuiteLongName    +5
     *
     PName+++++++++++..B...................Keywords+++++++++++++++++++++++++++++
     PContinuedName+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
     * Long name specified on Procedure spec:
     P ThisNameIsSoMuchLongerThanThe...
     P    PreviousNamesThatItMustBe...
     P    ContinuedOnSeveralSpecs...
     P                 B
     D ThisNameIsSoMuchLongerThanThe...
     D    PreviousNamesThatItMustBe...
     D    ContinuedOnSeveralSpecs...
     D                 PI            10A
     D parm_1                        10A   VALUE