CEEDATM: 将秒转换为字符时间戳记

input_seconds (输入)

64 位长浮点数，表示自 1582 年 10 月 14 日 00:00:00 以来的秒数，不计入闰秒。

例如， 1582 年 10 月 15 日的 00:00:01 是第二个数字 86,401 (24 * 60 * 60 + 01)。 输入秒数的有效范围为86400到265621679， 999.999 （ 23:59:59.999 31 December 9999）。

picture_string (输入)

半字长度前缀字符串，表示 output_timestamp的 必需 格式，例如 MM/DD/YY HH:MI AP。

picture_string 中的每个字符表示 output_timestamp中的一个字符。 如果在图片字符串中使用了斜杠 (/) 之类的定界符，那么会将它们按原样复制到 output_timestamp。

如果 picture_string 包含日语 Era 符号 <JJJJ>，那么 output_timestamp 中的 YY 位置表示日语 Era 中的年份。

output_timestamp (输出)

将 input_seconds 转换为 picture_string指定的格式所生成的固定长度 80 个字符的字符串。

如果需要，输出将截断为 output_timestamp的长度。

如果 input_seconds 无效，那么 output_timestamp 将设置为所有空白，并且 CEEDATM 将使用 non-CEE000 符号反馈代码终止。

fc (输出)

指示此服务结果的 12 字节反馈代码 (可选)。

用法说明: CEEDATM 的逆函数是 CEESECS ，它将时间戳记转换为秒数。

示例

*************************************************
**                                             **
** Function: CEEDATM - convert seconds to      **
**                     character time stamp    **
**                                             **
** In this example, a call is made to CEEDATM  **
** to convert a date represented in Lilian     **
** seconds (the number of seconds since        **
** 00:00:00 14 October 1582) to a character    **
** format (such as 06/02/88 10:23:45). The     **
** result is displayed.                        **
**                                             **
*************************************************
 IDENTIFICATION DIVISION.
 PROGRAM-ID. CBLDATM.
 DATA DIVISION.
 WORKING-STORAGE SECTION.
 01  DEST          PIC S9(9) BINARY VALUE 2.
 01  SECONDS                 COMP-2.
 01  IN-DATE.
     02  Vstring-length      PIC S9(4) BINARY.
     02  Vstring-text.
         03  Vstring-char    PIC X
                     OCCURS 0 TO 256 TIMES
                     DEPENDING ON Vstring-length
                         of IN-DATE.
 01  PICSTR.
     02  Vstring-length      PIC S9(4) BINARY.
     02  Vstring-text.
         03  Vstring-char    PIC X
                     OCCURS 0 TO 256 TIMES
                     DEPENDING ON Vstring-length
                        of PICSTR.
 01  TIMESTP                 PIC X(80).
 01  FC.
     02  Condition-Token-Value.
     COPY  CEEIGZCT.
         03  Case-1-Condition-ID.
             04  Severity    PIC S9(4) COMP.
             04  Msg-No      PIC S9(4) COMP.
         03  Case-2-Condition-ID
                   REDEFINES Case-1-Condition-ID.
             04  Class-Code  PIC S9(4) COMP.
             04  Cause-Code  PIC S9(4) COMP.
         03  Case-Sev-Ctl    PIC X.
         03  Facility-ID     PIC XXX.
     02  I-S-Info            PIC S9(9) COMP.
*
 PROCEDURE DIVISION.
 PARA-CBLDATM.
*************************************************
** Call CEESECS to convert time stamp of 6/2/88**
**     at 10:23:45 AM to Lilian representation **
*************************************************
     MOVE 20 TO Vstring-length of IN-DATE.
     MOVE '06/02/88 10:23:45 AM'
         TO Vstring-text of IN-DATE.
     MOVE 20 TO Vstring-length of PICSTR.
     MOVE 'MM/DD/YY HH:MI:SS AP'
         TO Vstring-text of PICSTR.
     CALL 'CEESECS' USING IN-DATE, PICSTR,
                          SECONDS, FC.

*************************************************
** If CEESECS runs successfully, display result**
*************************************************
     IF  CEE000 of FC  THEN
         DISPLAY Vstring-text of IN-DATE
             ' is Lilian second:  ' SECONDS
     ELSE
         DISPLAY 'CEESECS failed with msg '
             Msg-No of FC UPON CONSOLE
         STOP RUN
     END-IF.

*************************************************
** Specify required format of the output.       **
*************************************************
     MOVE 35 TO Vstring-length OF PICSTR.
     MOVE 'ZD Mmmmmmmmmmmmmmz YYYY at HH:MI:SS'
             TO Vstring-text OF PICSTR.

*************************************************
** Call CEEDATM to convert Lilian seconds to   **
**     a character time stamp                  **
*************************************************
     CALL 'CEEDATM' USING SECONDS, PICSTR,
                          TIMESTP, FC.

*************************************************
** If CEEDATM runs successfully, display result**
*************************************************
     IF CEE000 of FC  THEN
         DISPLAY 'Input seconds of ' SECONDS
             ' corresponds to: ' TIMESTP
     ELSE
         DISPLAY 'CEEDATM failed with msg '
             Msg-No of FC UPON CONSOLE
         STOP RUN
     END-IF.

     GOBACK.

下表显示了 CEEDATM 的样本输出。

示例：日期和时间图片字符串