示例: 格式化输出的日期

许多可调用服务都提供了需要广泛编码的功能。 这两种服务是 CEEDAYS 和 CEEDATE ，您可以在想要格式化日期时有效使用这两种服务。

CBL QUOTE
       ID DIVISION.
       PROGRAM-ID. HOHOHO.
      ************************************************************
      * FUNCTION:  DISPLAY TODAY'S DATE IN THE FOLLOWING FORMAT: *
      *            WWWWWWWWW, MMMMMMMM DD, YYYY                  *
      *                                                          *
      *            For example:  MONDAY, OCTOBER 18, 2010        *
      *                                                          *
      ************************************************************
       ENVIRONMENT DIVISION.
       DATA DIVISION.
       WORKING-STORAGE SECTION.

       01   CHRDATE.
           05 CHRDATE-LENGTH     PIC S9(4) COMP VALUE 10.
           05 CHRDATE-STRING     PIC X(10).
       01   PICSTR.
           05 PICSTR-LENGTH      PIC  S9(4) COMP.
           05 PICSTR-STRING      PIC  X(80).

       77   LILIAN PIC           S9(9) COMP.
       77   FORMATTED-DATE       PIC X(80).

       PROCEDURE DIVISION.
      ***************************************************************
      *    USE  DATE/TIME CALLABLE SERVICES TO PRINT OUT            *
      *    TODAY'S DATE FROM COBOL ACCEPT STATEMENT.                *
      ***************************************************************
           ACCEPT CHRDATE-STRING FROM DATE.

           MOVE "YYMMDD" TO PICSTR-STRING.
           MOVE 6 TO PICSTR-LENGTH.
           CALL "CEEDAYS" USING CHRDATE , PICSTR , LILIAN , OMITTED.

           MOVE " WWWWWWWWWZ, MMMMMMMMMZ DD, YYYY " TO PICSTR-STRING.
           MOVE 50 TO PICSTR-LENGTH.
           CALL "CEEDATE" USING LILIAN , PICSTR , FORMATTED-DATE ,
                 OMITTED.

           DISPLAY "******************************".
           DISPLAY FORMATTED-DATE.
           DISPLAY "******************************".

           STOP RUN.