範例 (CSPLAN 指令)

簡式範例設計

CSPLAN SAMPLE
  /PLAN FILE='/survey/myfile.csplan'
  /DESIGN
  /METHOD TYPE=SIMPLE_WOR
  /SIZE VALUE=100.

即會建立單一階段範例設計，並儲存在 myfile.csplan中。
當 CSSELECT 程序執行樣本設計時，將從作用中檔案選取 100 個觀察值。
該提取方法是簡單的隨機取樣，無需置換。
計劃檔案還包括使用 EQUAL_WOR 預估器 (使用 SIMPLE_WOR 方法擷取單位時的預設值) 的預設分析設計。

分層樣本設計

CSPLAN SAMPLE
  /PLAN FILE='/survey/myfile.csplan'
  /DESIGN STRATA=region 
  /METHOD TYPE=SIMPLE_WOR
  /RATE MATRIX=REGION; 'East' 0.1 ; 'West' 0.2; 
                       'North' 0.1; 'South' 0.3.

分層樣本設計是以階層的不成比例取樣率指定。範例元素將在每一個區域內獨立繪製。
該提取方法是簡單的隨機取樣，無需置換。
CSPLAN 會使用 region 作為分層變數及 EQUAL_WOR 估計值來產生預設分析設計。

分層叢集樣本設計

CSPLAN SAMPLE
  /PLAN FILE='/survey/myfile.csplan'
  /DESIGN STRATA=region CLUSTER=school 
  /METHOD TYPE=PPS_WOR
  /SIZE VALUE=10
  /MOS VARIABLE=mysizevar.

指定分層叢集樣本設計。
將在每個區域內挑選 10 所學校，其可能性與規模成比例。
從 米西澤瓦爾讀取階層的大小值。
CSPLAN 會使用 region 作為分層變數，並使用學校作為叢集變數，來產生預設分析設計。
UNEQUAL_WOR 估計值將用於分析。以機率與大小成比例的方式對單位進行取樣時， UNEQUAL_WOR 是預設值。

多階段叢集範例設計

CSPLAN SAMPLE
  /PLAN FILE='/survey/myfile.csplan'
  /DESIGN STAGELABEL='school districts' CLUSTER=district 
  /METHOD TYPE=PPS_WOR
  /RATE VALUE=.2
  /MOS VARIABLE=districtsize 
  /DESIGN STAGELABEL='schools' CLUSTER=school 
  /METHOD TYPE=SIMPLE_WOR
  /RATE VALUE=0.3.

已指定多階段叢集範例設計。
20% 的學區將按比例繪製。
在每個選定的學校分區內，百分之三十的學校將會被抽中而毋須更換。
CSPLAN 會產生預設分析設計。由於在階段 1 中指定 PPS_WOR 取樣方法，因此將使用 UNEQUAL_WOR 估計值進行該階段的分析。將使用 EQUAL_WOR 方法來分析階段 2。

簡式分析設計

CSPLAN ANALYSIS
  /PLAN FILE='/survey/myfile.csaplan'
  /PLANVARS ANALYSISWEIGHT=sampleweight
  /DESIGN
  /ESTIMATOR TYPE=EQUAL_WOR
  /POPSIZE VALUE=5000.

已指定分析設計。
變數 sampleweight 指定為包含用於分析的樣本加權的變數。
EQUAL_WOR 估計值將用於分析。
POPSIZE 指定樣本是從 5,000 個母群中取得。

簡式分析設計

CSPLAN ANALYSIS
  /PLAN FILE='/survey/myfile.csaplan'
  /PLANVARS ANALYSISWEIGHT=sampleweight
  /DESIGN
  /ESTIMATOR TYPE=EQUAL_WOR
  /INCLPROB VALUE=0.10.

已指定分析設計。
變數 sampleweight 指定為包含用於分析的樣本加權的變數。
EQUAL_WOR 估計值將用於分析。
INCLPROB 指定已選取 10% 的母體單位來併入樣本中。

分層分析設計

CSPLAN ANALYSIS 
  /PLAN FILE='/survey/myfile.csaplan'
  /PLANVARS ANALYSISWEIGHT=sampleweight
  /DESIGN STRATA=region 
  /ESTIMATOR TYPE=EQUAL_WOR
  /INCLPROB MATRIX=REGION; 'East' 0.1; 'West' 0.2; 
                           'North' 0.1; 'South' 0.3.

分析設計指定樣本由地區分層。
為每個階層指定包含機率。
變數 sampleweight 指定為包含用於分析的樣本加權的變數。

分層叢集分析設計

CSPLAN ANALYSIS 
  /PLAN FILE='/survey/myfile.csaplan'
  /PLANVARS ANALYSISWEIGHT=sampleweight
  /DESIGN STRATA=district CLUSTER=school 
  /ESTIMATOR TYPE=UNEQUAL_WOR.

分析設計指定使用分層叢集對單元進行取樣。
變數 sampleweight 指定為包含用於分析的樣本加權的變數。
地區定義為分層變數，而學校定義為集群變數。
UNEQUAL_WOR 估計值將用於分析。

多階段分析設計

CSPLAN ANALYSIS 
  /PLAN FILE='/survey/myfile.csaplan'
  /PLANVARS ANALYSISWEIGHT=sampleweight
  /DESIGN CLUSTER=district 
  /ESTIMATOR TYPE=UNEQUAL_WOR
  /DESIGN CLUSTER=school 
  /ESTIMATOR TYPE=EQUAL_WOR
  /INCLPROB VARIABLE=sprob.

分析設計指定使用多階段叢集作業對觀察值進行取樣。學校被抽樣在地區內。
UNEQUAL_WOR 預估器將在階段 1 中使用。
將在階段 2 中使用 EQUAL_WOR 估計值。
變數 sprob 包含第二階段分析所需的包含機率。
變數 sampleweight 指定為包含用於分析的樣本加權的變數。

顯示計劃

CSPLAN  VIEW
  /PLAN FILE='/survey/myfile.csplan'.

語法會顯示計劃檔案 myfile.csplan中的規格。