Examples: parsing XML
This example shows the basic organization of an XML PARSE statement and a processing procedure, where the XML document is in a COBOL data item. The XML document is given in the source so that you can follow the flow of the parse. The output of the program is given below. Compare the document to the output of the program to follow the interaction of the parser and the processing procedure and to match events to document fragments.
Example: parsing XML from a data item
Process APOST
Identification division.
Program-id. xmlsampl1.
Data division.
Working-storage section.
******************************************************************
* XML document, encoded as initial values of data items. *
******************************************************************
1 xml-document.
2 pic x(39) value '<?xml version=“1.0” encoding=“ibm-37”'.
2 pic x(19) value ' standalone=“yes”?>'.
2 pic x(39) value '<!--This document is just an example-->'.
2 pic x(10) value '<sandwich>'.
2 pic x(35) value ' <bread type=“baker's best”/>'.
2 pic x(41) value ' <?spread please use real mayonnaise ?>'.
2 pic x(31) value ' <meat>Ham & turkey</meat>'.
2 pic x(40) value ' <filling>Cheese, lettuce, tomato, etc.'.
2 pic x(10) value '</filling>'.
2 pic x(35) value ' <![CDATA[We should add a <relish>'.
2 pic x(22) value ' element in future!]]>'.
2 pic x(31) value ' <listprice>$4.99 </listprice>'.
2 pic x(27) value ' <discount>0.10</discount>'.
2 pic x(11) value '</sandwich>'.
1 xml-document-length computational pic 999.
******************************************************************
* Sample data definitions for processing numeric XML content. *
******************************************************************
1 current-element pic x(30).
1 list-price computational pic 9v99 value 0.
1 discount computational pic 9v99 value 0.
1 display-price pic $$9.99.
Procedure division.
mainline section.
XML PARSE xml-document PROCESSING PROCEDURE xml-handler
ON EXCEPTION
display 'XML document error ' XML-CODE
NOT ON EXCEPTION
display 'XML document successfully parsed'
END-XML
******************************************************************
* Process the transformed content and calculate promo price. *
******************************************************************
display ' '
display '-----+++++***** Using information from XML '
'*****+++++-----'
display ' '
move list-price to display-price
display ' Sandwich list price: ' display-price
compute display-price = list-price * (1 - discount)
display ' Promotional price: ' display-price
display ' Get one today!'
goback.
xml-handler section.
evaluate XML-EVENT
* ==> Order XML events most frequent first
when 'START-OF-ELEMENT'
display 'Start element tag: <' XML-TEXT '>'
move XML-TEXT to current-element
when 'CONTENT-CHARACTERS'
display 'Content characters: <' XML-TEXT '>'
* ==> Transform XML content to operational COBOL data item...
evaluate current-element
when 'listprice'
* ==> Using function NUMVAL-C...
compute list-price = function numval-c(XML-TEXT)
when 'discount'
compute discount = function numval-c(XML-TEXT)
end-evaluate
when 'END-OF-ELEMENT'
display 'End element tag: <' XML-TEXT '>'
move spaces to current-element
when 'START-OF-DOCUMENT'
compute xml-document-length = function length(XML-TEXT)
display 'Start of document: length=' xml-document-length
' characters.'
when 'END-OF-DOCUMENT'
display 'End of document.'
when 'VERSION-INFORMATION'
display 'Version: <' XML-TEXT '>'
when 'ENCODING-DECLARATION'
display 'Encoding: <' XML-TEXT '>'
when 'STANDALONE-DECLARATION'
display 'Standalone: <' XML-TEXT '>'
when 'ATTRIBUTE-NAME'
display 'Attribute name: <' XML-TEXT '>'
when 'ATTRIBUTE-CHARACTERS'
display 'Attribute value characters: <' XML-TEXT '>'
when 'ATTRIBUTE-CHARACTER'
display 'Attribute value character: <' XML-TEXT '>'
when 'START-OF-CDATA-SECTION'
display 'Start of CData: <' XML-TEXT '>'
when 'END-OF-CDATA-SECTION'
display 'End of CData: <' XML-TEXT '>'
when 'CONTENT-CHARACTER'
display 'Content character: <' XML-TEXT '>'
when 'PROCESSING-INSTRUCTION-TARGET'
display 'PI target: <' XML-TEXT '>'
when 'PROCESSING-INSTRUCTION-DATA'
display 'PI data: <' XML-TEXT '>'
when 'COMMENT'
display 'Comment: <' XML-TEXT '>'
when 'EXCEPTION'
compute xml-document-length = function length (XML-TEXT)
display 'Exception ' XML-CODE ' at offset '
xml-document-length '.'
when other
display 'Unexpected XML event: ' XML-EVENT '.'
end-evaluate
.
End program xmlsampl1.