IBM Lotus Domino Designer 8.5
  バージョン 8.5 および 8.5.1

日付/時刻

LotusScript には日付/時刻のデータ型がなく、 日付/時刻の値を持つ変数を宣言できません。ただし、LotusScript では内部的に日付が認識され、日付/時刻の値を入力、取得、操作するために使用する関数の集合が用意されています。日付/時刻の値は、8 バイト (倍精度) 浮動小数点数値として格納されます。整数部分は西暦 100 年 1 月 1 日から数えた通算日を表し、小数部分は時刻を 1 日の分数として表します。日付用に許容される値の範囲は、-657434 (西暦 100 年 1 月 1 日) から 2958465 (9999 年 12 月 31 日) までです。0 は西暦 1899 年 12 月 30 日を表します。

日付/時刻の値を保持して操作するには、Variant 型の変数を使用します。このような値は、以下の関数のいずれかを呼び出すことにより、生成できます。

注 日付/時刻の値を含む Variant 型の変数を加算して、日付/時刻値を含む Variant 型の変数をもう 1 つ作成してもよいです。ただし、日付/時刻の値を含む Variant 型の変数をもう 1 つの Variant 型の変数から減算すると、Double の Variant 型になります。Cdat 関数を使用して変数を日付/時刻の値に変換し直す必要があります。

DataType または TypeName 関数を使用すると、Variant 型の変数に日付または日付/時刻の値が入っているかどうかを調べられます。このような値が入っている場合、DataType は値 7 を返し、TypeName は DATE を返します。

次の例は、日付および日付/時刻の値を取得できるさまざまな方法、それらの値を Variant 型の変数に代入する方法、およびそれらの値に関して実行できるいくつかの操作 (ある期間の計算や、指定された日付の曜日を特定することなど) を示しています。

今日が 1994 年 10 月 26 日で、時刻が 7:49:23 AM だとして、次の変数を宣言します。

Dim theInstantV As Variant

Dim theDateV As Variant

Dim theDateValV As Variant

Dim myDate As String

次の例では、Now 関数を呼び出して現在の日付と時刻を取得し、その結果を Variant 型の変数 InstantV に代入します。

theInstantV = Now

Print theInstantV

' Output:10/26/94 7:49:23 AM

次の例では、(月の) 日にちと時間 (時分秒の時の部分) に対応する整数を表示します。

Print Day(theInstantV) & " " & Hour(theInstantV)

' Output: 26 7

次の例では、現在の日付を Variant 型の変数 theDateV に代入します。

theDateV = Date

Print theDateV

' Output:10/26/94

Print theDateV - 1

' Output: 10/25/94 

次の例では、現在の日付の値を Double 型の値に変換します。

Print CDbl(theDateV)

' Output:34633

' Convert a value of type Double

' to a date value, assign it to a

' Variant variable, and print it.

theDateV = CDat(34633)

Print theDateV

' Output: 10/26/94

次の例では、現在の年、月、日の整数表記を取得し、月と日の値を増やして、その結果をある Integer 型の変数に代入し、DateNumber に渡します。DateNumber はそれらの値に基づいて日付を計算して戻し、Variant 型の変数 theDateV に代入します。

y% = Year(theDateV)

m% = Month(theDateV) + 1

d% = Day(theDateV) + 1

theDateV = DateNumber(y%, m%, d%)

Print theDateV

' Output: 11/27/94

次の例では、日付として解釈できる文字列を String 型の変数 myDate$ に代入し、それを日付/時刻の値に変換して計算を実行し (1 日を減算する)、結果の日付を返します。

myDate$ = "October 28, 1994"

Print DateValue(myDate$) - 1

' Output:10/27/94

theDateV = DateValue(myDate$)

' Check the data type of the value

' held by the Variant variable theDateV.

Print TypeName(theDateV)

' Output:DATE 型

次の例では、特定の出力形式で日付を表示します。

Print Format(DateValue("10-18-14"), "mmm-d-yyyy")

' Output:Oct-18-1914

注 2 桁年数の解釈の仕方は、さまざまな製品で異なります。たとえば Lotus Notes では、同じ値を Oct-18-2014 と表示します。

次の例では、現在の日付の日付/時刻の値を Double 型の値に変換します。

Print CDbl(Date)

' Output: 34633

次の例では、特定の日付の日付/時刻の値を Double 型の値に変換します。これは、値を String 型として DateValue に渡し、その結果を (Double 型の値に変換する) CDbl に渡すことによって行います。

Print CDbl(DateValue("10-18-14"))

' Output:5405

Print CDbl(Date) - CDbl(DateValue("10-18-14"))

' Output: 29228

次の例では、2 つの日付の間の日数を計算します。

theDateV = DateValue(Date)

' theDateV = 10/26/94

y% = Year(theDateV)

m% = Month(theDateV) + 1

d% = Day(theDateV) + 1

theDateValV = DateNumber(y%, m%, d%)

' theDateValV = 11/27/94

Print CDbl(theDateValV) - CDbl(theDateV)

' Output: 32

注 最初に Double に変換しないで日付の減算を行うと、Double の Variant 型になります。

次の例では、特定の日付が何曜日になるかを調べます。日曜日は 1 です。

Print Weekday(theDateValV)

' Output: 1 

値の整数部分がゼロの場合、その値は時刻値として解釈されます。

Print CDat(0)		'Prints "12:00:00 AM"

Print CDat(.0)		'Prints "12:00:00 AM"

Print CDat(0.0)		'Prints "12:00:00 AM"

Print CDat(0.1)		'Prints "2:24:00 AM"

値の小数部分がゼロの場合、その値は日付値として解釈されます。

Print CDat(1.0)		'Prints "12/31/1899"

Print CDat(2.0)		'Prints "1/1/1900"

Print CDat(123456.0)	'Prints "1/3/2238"

---

ライブラリー | サポート | ご利用条件 |

最終更新日: 2009 年 10 月 5 日 (月曜日)