REXX-EXEC RSSERVER Sample Program
The server sample program (RSSERVER EXEC) shows an example of how to use sockets in nonblocking mode. The program waits for connect requests from client programs, accepts the requests, and then sends data. The sample can handle multiple client requests in parallel processing.
The server program sets up a socket to accept connection requests from clients and waits in a loop for events reported by the select call. If a socket event occurs, it is processed. A read event can occur on the original socket for accepting connection requests and on sockets for accepted socket requests. A write event can occur only on sockets for accepted socket requests.
A read event on the original socket for connection requests means that a connection request from a client occurred. Read events on other sockets indicate either that there is data to receive or that the client has closed the socket. Write events indicate that the server can send more data. The server program sends only one line of data in response to a write event.
The server program keeps a list of sockets to which it wants to
write. It keeps this list to avoid unwanted socket events. The TCP/IP
protocol is not designed for one single-threaded program communicating
on many different sockets, but for multithread applications where
one thread processes only events from a single socket.
trace o
signal on syntax
signal on halt
/* Set error code values */
initialized = 0
parse arg argstring
argstring = strip(argstring)
if substr(argstring,1,1) = '?' then do
say 'RSSERVER and RSCLIENT are a pair of programs which provide an'
say 'example of how to use REXX/SOCKETS to implement a service. The'
say 'server must be started before the clients get started. '
say ' '
say 'The RSSERVER program runs on a VM Userid. '
say 'It returns a number of data lines as requested to the client. '
say 'It is started with the command: RSSERVER '
say 'and terminated by issuing HX. '
say ' '
say 'The RSCLIENT program is used to request a number of arbitrary'
say 'data lines from the server. One or more clients can access '
say 'the server until it is terminated. '
say 'It is started with the command: RSCLIENT number <server> '
say 'where "number" is the number of data lines to be requested and'
say '"server" is the ipaddress of the service virtual machine. (The'
say 'default ipaddress is the one of the host on which RSCLIENT is'
say 'running, assuming that RSSERVER runs on the same host.) '
say ' '
exit 100
end
/* Split arguments into parameters and options */
parse upper var argstring parameters '(' options ')' rest
/* Parse the parameters */
parse var parameters rest
if rest¬='' then call error 'E', 24, 'Invalid parameters specified'
/* Parse the options */
do forever
parse var options token options
select
when token='' then leave
otherwise call error 'E', 20, 'Invalid option "'token'"'
end
end
/* Initialize control information */
port = '1952' /* The port used for the service */
/* Initialize */
say 'RSSERVER: Initializing'
call Socket 'Initialize', 'RSSERVER'
if src=0 then initialized = 1
else call error 'E', 200, 'Unable to initialize SOCKET'
ipaddress = Socket('GetHostId')
if src¬=0 then call error 'E', 200, 'Unable to get the local ipaddress'
say 'RSSERVER: Initialized: ipaddress='ipaddress 'port='port
/* Initialize for accepting connection requests */
s = Socket('Socket')
if src¬=0 then call error 'E', 32, 'SOCKET(SOCKET) rc='src
call Socket 'Bind', s, 'AF_INET' port ipaddress
if src¬=0 then call error 'E', 32, 'SOCKET(BIND) rc='src
call Socket 'Listen', s, 10
if src¬=0 then call error 'E', 32, 'SOCKET(LISTEN) rc='src
call Socket 'Ioctl', s, 'FIONBIO', 'ON'
if src¬=0 then call error 'E', 36, 'Cannot set mode of socket' s
/* Wait for new connections and send lines */
timeout = 60
linecount. = 0
wlist = ''
do forever
/* Wait for an event */
if wlist¬='' then sockevtlist = 'Write'wlist 'Read * Exception'
else sockevtlist = 'Write Read * Exception'
sellist = Socket('Select',sockevtlist,timeout)
if src¬=0 then call error 'E', 36, 'SOCKET(SELECT) rc='src
parse upper var sellist . 'READ' orlist 'WRITE' owlist 'EXCEPTION' .
if orlist¬='' | owlist^='' then do
event = 'SOCKET'
if orlist¬='' then do
parse var orlist orsocket .
rest = 'READ' orsocket
end
else do
parse var owlist owsocket .
rest = 'WRITE' owsocket
end
end
else event = 'TIME'
select
/* Accept connections from clients, receive and send messages */
when event='SOCKET' then do
parse var rest keyword ts .
/* Accept new connections from clients */
if keyword='READ' & ts=s then do
nsn = Socket('Accept',s)
if src=0 then do
parse var nsn ns . np nia .
say 'RSSERVER: Connected by' nia 'on port' np 'and socket' ns
end
end
/* Get nodeid, userid and number of lines to be sent */
if keyword='READ' & ts¬=s then do
parse value Socket('Recv',ts) with len nid uid count .
if src=0 & len>0 & datatype(count,'W') then do
if count<0 then count = 0
if count>5000 then count = 5000
ra = 'by' uid 'at' nid
say 'RSSERVER: Request for' count 'lines on socket' ts ra
linecount.ts = linecount.ts + count
call addsock(ts)
end
else do
call Socket 'Close',ts
linecount.ts = 0
call delsock(ts)
say 'RSSERVER: Disconnected socket' ts
end
end
/* Get nodeid, userid and number of lines to be sent */
if keyword='WRITE' then do
if linecount.ts>0 then do
num = random(1,sourceline()) /* Return random-selected */
msg = sourceline(num) || '15'x /* line of this program */
call Socket 'Send',ts,msg
if src=0 then linecount.ts = linecount.ts - 1
else linecount.ts = 0
end
else do
call Socket 'Close',ts
linecount.ts = 0
call delsock(ts)
say 'RSSERVER: Disconnected socket' ts
end
end
end
/* Unknown event (should not occur) */
otherwise nop
end
end
/* Terminate and exit */
call Socket 'Terminate'
say 'RSSERVER: Terminated'
exit 0
/* Procedure to add a socket to the write socket list */
addsock: procedure expose wlist
s = arg(1)
p = wordpos(s,wlist)
if p=0 then wlist = wlist s
return
/* Procedure to del a socket from the write socket list */
delsock: procedure expose wlist
s = arg(1)
p = wordpos(s,wlist)
if p>0 then do
templist = ''
do i=1 to words(wlist)
if i¬=p then templist = templist word(wlist,i)
end
wlist = templist
end
return
/* Calling the real SOCKET function */
socket: procedure expose initialized src
a0 = arg(1)
a1 = arg(2)
a2 = arg(3)
a3 = arg(4)
a4 = arg(5)
a5 = arg(6)
a6 = arg(7)
a7 = arg(8)
a8 = arg(9)
a9 = arg(10)
parse value 'SOCKET'(a0,a1,a2,a3,a4,a5,a6,a7,a8,a9) with src res
return res
/* Syntax error routine */
syntax:
call error 'E', rc, '==> REXX Error No.' 20000+rc
return
/* Halt exit routine */
halt:
call error 'E', 4, '==> REXX Interrupted'
return
/* Error message and exit routine */
error:
type = arg(1)
retc = arg(2)
text = arg(3)
ecretc = right(retc,3,'0')
ectype = translate(type)
ecfull = 'RXSSRV' || ecretc || ectype
say '===> Error:' ecfull text
if type¬='E' then return
if initialized
then do
parse value Socket('SocketSetStatus') with . status severreason
if status¬='Connected'
then say 'The status of the socket set is' status severreason
end
call Socket 'Terminate'
exit retc