DESIGN Subcommand (GENLOG command)

DESIGN specifies the model to be fit. If DESIGN is omitted or used with no specifications, the saturated model is produced. The saturated model fits all main effects and all interaction effects.

  • Only one design can be specified on the subcommand.
  • To obtain main-effects models, name all of the variables listed on the variables specification.
  • To obtain interactions, use the keyword BY or an asterisk (*) to specify each interaction, for example, A BY B or C*D. To obtain the single-degree-of-freedom partition of a specified factor, specify the partition in parentheses following the factor (see the example below).
  • To include cell covariates in the model, first identify them on the variable list by naming them after the keyword WITH, and then specify the variable names on DESIGN.
  • Effects that involve only independent variables result in redundancy. GENLOG removes these effects from the model.
  • If your variable list includes a cell covariate (identified by the keyword WITH), you cannot imply the saturated model by omitting DESIGN or specifying it alone. You need to request the model explicitly by specifying all main effects and interactions on DESIGN.

Example

COMPUTE X=MONTH.
GENLOG MONTH WITH X
  /DESIGN X.
  • This example tests the linear effect of the dependent variable.
  • The variable specification identifies MONTH as a categorical variable. The keyword WITH identifies X as a covariate.
  • DESIGN tests the linear effect of MONTH.

Example

GENLOG A B
  /DESIGN=A.


GENLOG A B
  /DESIGN=A,B.
  • Both designs specify main-effects models.
  • The first design tests the homogeneity of category probabilities for B; it fits the marginal frequencies on A but assumes that membership in any of the categories of B is equiprobable.
  • The second design tests the independence of A and B. It fits the marginals on both A and B.

Example

GENLOG A  B  C 
  /DESIGN=A,B,C, A BY B.
  • This design consists of the A main effect, the B main effect, the C main effect, and the interaction of A and B.

Example

GENLOG A BY B
 /MODEL=MULTINOMIAL
 /DESIGN=A,A BY B(1).
  • This example specifies single-degree-of-freedom partitions.
  • The value 1 following B to the first category of B.

Example

GENLOG HUSED WIFED WITH DISTANCE
  /DESIGN=HUSED WIFED DISTANCE.
  • The continuous variable DISTANCE is identified as a cell covariate by the keyword WITH. The cell covariate is then included in the model by naming it on DESIGN.

Example

COMPUTE  X=1.
GENLOG  MONTH WITH X
  /DESIGN=X.
  • This example specifies an equiprobability model.
  • The design tests whether the frequencies in the table are equal by using a constant of 1 as a cell covariate.