Within-Cells Record Definition (MATRIX DATA command)

When the data include factors and ROWTYPE_ is not specified, CONTENTS distinguishes between within-cells and pooled records by enclosing the keywords for within-cells records in parentheses.

  • If the records associated with the within-cells keywords appear together for each set of factor values, enclose the keywords together within a single set of parentheses.
  • If the records associated with each within-cells keyword are grouped together across factor values, enclose the keyword within its own parentheses.

Example

MATRIX DATA VARIABLES=F1 VAR1 TO VAR3 /FACTORS=F1 /CELLS=2
  /CONTENTS=(MEAN SD N) CORR.
  • MEAN, SD, and N contain within-cells information and are therefore specified within parentheses. CORR is outside the parentheses because it identifies pooled records.
  • CELLS is required because there is a factor specified and ROWTYPE_ is implicit.

Example

MATRIX DATA VARIABLES=F1 VAR1 TO VAR3 /FACTORS=F1 /CELLS=2
  /CONTENTS=(MEAN SD N) CORR.
BEGIN DATA
1  5  4  3
1  3  2  1
1  9  9  9
2  4  5  6
2  6  5  4
2  9  9  9
   1
  .6  1
  .7 .8  1
END DATA.
  • The parentheses around the CONTENTS keywords indicate that the mean, standard deviation, and N for value 1 of factor F1 are together, followed by the mean, standard deviation, and N for value 2 of factor F1.

Example

MATRIX DATA VARIABLES=F1 VAR1 TO VAR3 /FACTORS=F1 /CELLS=2
  /CONTENTS=(MEAN) (SD) (N) CORR.
BEGIN DATA
1  5  4  3
2  4  5  6
1  3  2  1
2  6  5  4
1  9  9  9
2  9  9  9
   1
  .6  1
  .7 .8  1
END DATA.
  • The parentheses around each CONTENTS keyword indicate that the data include the means for all cells, followed by the standard deviations for all cells, followed by the N values for all cells.

Example

MATRIX DATA VARIABLES=F1 VAR1 TO VAR3 /FACTORS=F1 /CELLS=2
  /CONTENTS=(MEAN SD) (N) CORR.
BEGIN DATA
1  5  4  3
1  3  2  1
2  4  5  6
2  6  5  4
1  9  9  9
2  9  9  9
   1
  .6  1
  .7 .8  1
END DATA.
  • The parentheses around the CONTENTS keywords indicate that the data include the mean and standard deviation for value 1 of F1, followed by the mean and standard deviation for value 2 of F1, followed by the N values for all cells.