Beispiele: Spalten programmieren

In den nachfolgenden Beispielen sind einige allgemeine Programmiertechniken für Spalten erläutert.

Text ausgehend von einem Feldwert bestimmen

Sie können in einer Spalte benutzerdefinierten Text anzeigen, der auf einer Bedingung oder verschiedenen Bedingungen basiert. Beispielsweise wäre eine Formel denkbar, die einen benutzerdefinierten Text anzeigt, wenn die Verkaufszahlen über einem bestimmten Wert liegen. Diese Formel überprüft den Wert "Verkauf_Februar" (ein Zahlenfeld), und zeigt Text an, der auf diesem Wert beruht:

@If(Verkauf_Februar>60000;"Guter Monat!";"")

Text ausgehend von einem Maskennamen bestimmen

In der Spalte "Betreff" der Ansicht "Alle Dokumente" in der Schablone "Mail" wird folgende Formel verwendet: (es wird eine Betreffzeile angezeigt, die auf der Maske basiert, mit der das Dokument erstellt wurde):

@If(Form = "NonDelivery Report"; "ZUSTELLUNGSFEHLER: " + FailureReason; Form = "Delivery Report"; "ZUGESTELLT: " + Subject; Form = "Return Receipt"; "EMPFANGEN: " + Subject; Form = "ReturnNonReceipt"; "NICHT EMPFANGEN: " + Subject; Subject)

Text und Datumswerte kombinieren

Sie können Text und Feldwerte in einer Spalte einer Datenbank für Terminplanung kombinieren, um die einzelnen Dokumente näher zu erläutern. In der folgenden Formel wird eine Textnachricht und ein Datum angezeigt. Dabei sind zwei Variationen möglich, abhängig von dem Wert im Feld "Sched". Der Parameter "D1S0" der Formel @Text ist eine Formatierungsoption, die überflüssige Informationen aus der Ansicht entfernt, indem nur Monat und Jahr des Datumsfeldes ohne Angabe des genauen Zeitpunkts angezeigt werden.

@If(Sched = "Besonderer Zeitplan"; "Besonderer Zeitplan für die Woche vom: " + @Text(Date; "D1S0"); "Mein regulärer Zeitplan ab " + @Text(@Modified; "D1S0"))

Text und Namen kombinieren

Die folgende Formel ergibt eines von drei möglichen Ergebnissen, basierend auf dem Status der Anfrage:

@If(Status="Zurückgewiesen";"Zurückgewiesen von " + LastApproveName; SignatureCount=0; "Originalanfrage";"Genehmigt von " + LastApproveName)

Wurde die Anforderung zurückgewiesen, wird in der Spalte der Text "Zurückgewiesen von" in Verbindung mit dem Namen der Person angezeigt, die die Maske zuletzt signiert hat.
Enthält die Anfrage keine Signaturen (was bedeutet, dass kein Antragsprüfer die Anfrage bearbeitet hat), wird in der Spalte der Text "Originalanfrage" angezeigt.
Wurde die Anfrage genehmigt, wird in der Spalte der Text "Genehmigt von" in Verbindung mit dem Namen der Person angezeigt, die die Maske zuletzt signiert hat.

Datum der Dokumenterstellung anzeigen

Die Spalte "Erstellt" in der Ansicht "Nach Autor" der Schablone "Dokumentbibliothek" verwendet die folgende Formel, um das Erstellungsdatum des Dokuments anzuzeigen:

@Created

Erweiterbare Ebenen (Variation der einfachen Funktion)

Die einfache Funktion "Komprimieren/Erweitern" (+/-) verwendet @IsExpandable ohne Argumente. Wenn Sie ein + (Pluszeichen) anzeigen möchten, wenn ein Dokument Antworten enthält, aber kein - (Minuszeichen), wenn Antworten erweitert werden, können Sie die folgende Formel verwenden:

@IsExpandable("+";"")

Zwei Feldwerte in einer Spalte anzeigen

Um die Namen und Telefonnummern von Personen in einer einzigen Spalte anzuzeigen, erstellen Sie eine Spalte, die in aufsteigender Reihenfolge (empfohlene Reihenfolge für alphabetische Listen) sortiert wird. Die folgende Formel trennt die beiden Feldwerte durch ein Leerzeichen:

Name + " " + Phone

"Vorgetäuschte" Einrückungen erstellen

Wenn Notes Antwortdokumente einrückt, wird immer dieselbe Einrückung verwendet. Wenn Sie Dokumente in einer einfachen Ansicht ohne Antwortdokumente einrücken möchten oder wenn Sie Dokumenttitel in derselben Spalte unterschiedlich einrücken möchten, können Sie in einem Feld der Maske bestimmen, wie weit die einzelnen Dokumente eingerückt werden, und außerdem den Dokumenttiteln in der Ansicht anhand einer Spaltenformel Leerzeichen hinzufügen. Die folgende Formel rückt Dokumente auf drei verschiedene Arten ein, je nachdem, welchen Wert das Feld "Einrücken" enthält. Lautet der Wert im Feld "Einrücken" beispielsweise 2, werden dem Betreff des Dokuments von Notes in der Spalte 18 Leerzeichen vorangestellt.

@If(Einrücken = 1; @Repeat(" "; 12) + Betreff; Einrücken = 2; @Repeat(" "; 18) + Betreff; @Repeat(" "; 6) + Betreff)

Dokumente nummerieren

In einer Ansicht "Nach Autor" werden die einzelnen Dokumente innerhalb jeder Kategorie eines Autors nummeriert (z. B. 1., 2., 3.)

@IsCategory("";@DocNumber("") + ". ")

Entspricht die Zeile einer Kategorie (der Name des Autors), gibt @IsCategory eine Nullzeichenfolge ("") zurück. Ist die Zeile keine Kategorie, stellt sie ein Dokument dar. Dabei gibt @DocNumber eine Zeichenfolge zurück, die die Eintragsnummer des entsprechenden Dokuments angibt. Die vollständige Eintragsnummer eines Dokuments lautet etwa 1.1, 1.2, 1.3 usw. Wird die Eintragsnummer in Verbindung mit einer Nullzeichenfolge ("") benutzt, gibt @DocNumber die rechte äußerste Komponente der Eintragsnummer zurück. Die Formel fügt einen Punkt und ein Leerzeichen hinter der Zahl ein.

Spaltenfarben programmseitig festlegen

In Notes-Clientanwendungen können Sie die Hintergrundfarbe und die Textfarbe für eine Spalte programmseitig festlegen, indem Sie links neben der betreffenden Spalte eine Spalte für die Farbsteuerung einfügen. Bei einer Spalte für die Farbsteuerung ist die Spalteneigenschaft "Wert als Farbe verwenden" aktiviert. Die zugehörige Formel bestimmt die Farben, die verwendet werden sollen. Die jeweilige Farbauswahl gilt für alle Spalten hinter der Spalte für die Farbsteuerung bis zur nächsten Spalte für die Farbsteuerung. Normalerweise werden zwei Spalten für die Farbsteuerung verwendet: eine vor und eine hinter den Spalten, deren Farbe festgelegt werden soll. Die möglichen Werte für die Spalte sind:

Ein Farbfeld, um die Textfarbe festzulegen, ohne die Hintergrundfarbe zu ändern.

Eine Liste mit zwei Farbfeldern, die durch einen Doppelpunkt getrennt werden. Das erste legt die Textfarbe, das zweite die Hintergrundfarbe fest. Beispielformel:

textcolor:bgcolor

Im nachstehenden Beispiel wird gezeigt, wie RGB-Farbwerte in Einzelsätzen und Paarsätzen verwendet werden können.

red := 255:0:0;
blue := 0:0:255;
yellow := 255:255:0;
pink := 255:193:253;
white := 255:255:255;
black :=  1:1:1;
apricot := 255:155:133;
plain:= 0:0:0;

@If (category = "Katzen";blue:red ;subcategory = "Halsbänder";pink;subcategory ="Leinen";black:plain;0:0:0);

Anmerkung: Sie müssen die Farbnamen nicht definieren. Sie können die numerischen Kombinationen direkt in eine Formel eingeben. Wenn Sie die Farben definieren, sehen Sie jedoch besser, was Sie tun, und die Wahrscheinlichkeit von Tippfehlern bei der häufigeren Verwendung einer Farbe wird verringert. Da das Definieren der Farben mit Wörtern einfacher ist als mit Zahlenkombinationen, werden die Daten selbst in den Farbspalten nicht angezeigt. Um die Kategorie "Katzen" beispielsweise in Rot anzuzeigen, benötigen Sie eine weitere Spalte zum Anzeigen der Kategorie.

Rot-, Grün- und Blauanteil der Textfarbe werden durch eine Liste mit drei Zahlenwerten im Bereich 0 bis 255 festgelegt. Die Hintergrundfarbe bleibt unverändert.

Rot-, Grün- und Blauanteil der Textfarbe und der Hintergrundfarbe werden durch eine Liste mit sechs Zahlenwerten im Bereich 0 bis 255 festgelegt.

Mit dem speziellen Wert -1:-1:-1 werden wieder die normalen Ansichtsfarben angezeigt.

Sie können Farbfelder und Zahlenlisten nicht mischen. "textcolor:255:255:0" funktioniert beispielsweise nicht, wenn "textcolor" ein Farbfeld ist. Das Farbfeld wird jedoch als Zeichenfolge von Hexadezimalziffern gespeichert, sodass Sie einen Farbfeldwert in der Spaltenformel als Text in Anführungszeichen fest codieren können, z.B. "colorfield: 00FFFF00".

Anmerkung: Normalerweise sollten Sie in den Spalten für die Farbsteuerung die Option "Spalte verbergen" aktivieren.

Sie können die Hintergrundfarbe und die Textfarbe für eine Spalte auch programmseitig festlegen, indem Sie die Option "Wert als Farbe verwenden" im Register "Info" der InfoBox "Eigenschaften: Spalte" wählen und anschließend RGB-Werte im Programmierfenster als Wert für die Spalte angeben.

Anmerkung: Diese Funktion wird im Web unterstützt, Sie müssen die RGB-Werte der Farbe als Zahlen angeben (z. B. 255:0:255). Farbwerte im Textformat (z. B. "FF00FF") werden nicht unterstützt.

Sie können auch den Spaltenwert auf einen Feldwert setzen, der die RGB-Farbwerte angibt. Diese Funktion können Sie in Verbindung mit dem Farbfeld verwenden, um einem Benutzer die Möglichkeit zu geben, eine Farbe mit einem Farbwähler festzulegen. Anschließend können Sie diese Farbe einer Ansichtskomponente zuweisen, zum Beispiel dem Text in einer Spalte. Weitere Informationen zur Verwendung dieser Funktion, um das Anpassen von Ansichtsfarben zu ermöglichen, finden Sie unter Benutzern ermöglichen, Farben in einer Ansicht festzulegen.