Введение в XSLT

Преобразование формата XML-данных посредством преобразований расширяемого языка таблиц стилей (XSLT)

Преобразовывать XML приходится так часто, что преобразования расширяемого языка таблиц стилей (XSLT) считаются одной из основных спецификаций XML. Автор данного руководства объясняет, как создавать таблицы стилей XSLT. Здесь также описаны основы XPath, который позволяет выбирать отдельные части XML-документа. Наконец, руководство дает читателю представление о некоторых более глубоких возможностях, которые предоставляет XSLT.

Николас Чейз, автор, Studio B

Николас Чейз (Nicholas Chase), автор Studio B (www.studiob.com), работает в области разработки web-сайтов для таких компанаий как Lucent Technologies, Sun Microsystems, Oracle и Tampa Bay Buccaneers. Ник работал учителем физики в средней школе, менеджером по низкоуровневой утечке радиоактивности, редактором интерактивного журнала по научной фантастике, инженером мультимедийных средств и инструктором по Oracle. Не так давно он был директором по технологии в компании, специализирующейся на интерактивных взаимодействиях в Clearwater, Florida. Николас является автором четырех книг по Web и XML-разработке, включая "XML Primer Plus" (Sams). Он любит общаться с читателями, и к нему можно обратиться по адресу nicholas@nicholaschase.com nicholas@nicholaschase.com.



12.01.2009

Перед началом работы

Данное руководство создано для разработчиков, которые хотят использовать XSLT для преобразования XML-данных в другие формы без необходимости программирования на Java™ или других языках.

В данном руководстве подразумевается, что вы знакомы с XML, однако автор не вдается в какие-то тайные особенности этого языка, поэтому базового понимания вполне достаточно. За исключением небольшого раздела про расширения, вам не нужно иметь за плечами никакого особенного языка программирования. И даже в этом разделе идеи очень просты и применимы к любому языку программирования, который поддерживается процессором.

О чем это руководство?

Это руководство - о преобразованиях расширяемого языка таблиц стилей (XSLT). XSLT - это одна из базовых спецификаций, связанных с XML, позволяющая легко переводить XML-данные из одной формы в другую.

В данном руководстве вы изучите:

  • Основы XSLT
  • Использование простых шаблонов
  • Публикацию данных
  • Управление пробелами
  • Основы XPath
  • Функции XPath
  • Циклы и условные операторы
  • Импорт и включение других таблиц стилей
  • Расширение XSLT
  • Переменные XSLT

Начало работы

Представьте на минуту, что у вас есть набор данных в XML. Возможно, вы предпочли хранить их таким образом из-за гибкости XML. Вы знаете, что сможете использовать их на разных платформах и практически с любым языком программирования. Но иногда вам придется менять форму вашего XML. Например, вам может понадобиться перевести данные в другой XML-формат, чтобы хранить их в другой системе, или в другую форму для представления, или еще для чего-нибудь.

Например, у вас могут быть данные в XML, которые вы хотите опубликовать в Интернете, что означает перевод их в HTML. Конечно, вы могли бы вручную просмотреть документ и сделать в нем необходимые изменения, или может быть, вы подумали о том, чтобы загрузить XML в DOM, а затем вручную создать документ вывода.

Что такое XSLT?

Преобразования расширяемого языка таблиц стилей (XSLT) предоставляют способ для автоматического перевода XML-данных из одной формы в другую. Целевая форма - это обычно другой XML-документ, но не обязательно; вы можете преобразовать XML практически во что угодно, просто создав таблицу стилей XSLT и обработав данные. Если вы хотите изменить результаты, вы просто меняете таблицу стилей и обрабатываете XML заново. Здесь есть дополнительное преимущество, расширяющее возможности непрограммистов, например, дизайнеров, которые могут изменять таблицу стилей и влиять на результаты.

Давайте посмотрим пример.

Поставленная задача

В данном руководстве мы возьмем XML-документ и преобразуем его в XHTML-документ, который можно отобразить как Web-страницу. Входные данные - это просто файл с рецептами (см. листинг 1).

Листинг 1. Основные данные
<recipes>
   <recipe>
       <name>Gush'gosh</name>
       <ingredients>
          
<ingredient><qty>1</qty><unit>pound</unit>
<food>hamburger</food></ingredient>
          
<ingredient><qty>1</qty><unit>pound</unit>
<food>elbow macaroni</food></ingredient>
          
<ingredient><qty>2</qty><unit>cups</unit>
<food>brown sugar</food></ingredient>
          <ingredient><qty>1</qty><unit>bag</unit>
<food>chopped onions</food></ingredient>
          
<ingredient><qty>1</qty><unit>teaspoon</unit>
<food>dried dill</food></ingredient>
       </ingredients>
       <instructions>
          <instruction>Brown the hamburger.</instruction>
          <instruction>Add onions and cook until
 transparent.</instruction>
          <instruction>Add brown sugar and dill.</instruction>
          <instruction>Cook and drain pasta.</instruction>
          <instruction>Combine meat and pasta.</instruction>
       </instructions>
   </recipe>
   
      <recipe>
       <name>A balanced breakfast</name>
       <ingredients>
          <ingredient><qty>1</qty><unit>cup</unit>
<food>cereal</food></ingredient>
          
<ingredient><qty>1</qty><unit>glass</unit>
<food>orange juice</food></ingredient>
          
<ingredient><qty>1</qty><unit>cup</unit>
<food>milk</food></ingredient>
          
<ingredient><qty>2</qty><unit>slices</unit>
<food>toast</food></ingredient>
       </ingredients>
       <instructions>
          <instruction>Combine cereal and milk in 
bowl.</instruction>
          <instruction>Add all ingredients to table.</instruction>
       </instructions>
   </recipe>

</recipes>

Замечание редактора: Эти рецепты –приведены просто для примера, так, как их представляет себе автор. Правильный рецепт для Gush'gosh (полученный от его жены, которая и готовит это блюдо) состоит из 1 фунта (0,454 кг) рубленой говядины, 1 фунта рожков, 1/2 стакана желтого сахара, 1 небольшого пакета (около 300 грамм) мелко нарезанного лука, 1 чайной ложки сушеного укропа и 1 небольшой банки томатной пасты, в которую добавляется желтый сахар.

Конечно, это очень простой пример, поэтому вы не увязнете в деталях самих данных, однако в виде XML-данных можно представить что угодно - от процесса журналирования до финансов.

Наша цель - преобразовать эти данные в XHTML-страницу, которая будет отображать рецепты по отдельности и форматировать их ингредиенты и инструкции по приготовлению (см. листинг 2).

Листинг 2. Результат
<?xml version="1.0" encoding="UTF-8"?>
<html xmlns="http://www.w3.org/TR/xhtml1/strict">
<head><title>Recipe</title></head>
<body>
<h2>Gush'gosh</h2>
<h3>Ingredients:</h3>
<p>       1 pound hamburger<br/>
          1 pound elbow macaroni<br/>
          2 cups brown sugar<br/>
          1 bag chopped onions<br/>
          1 teaspoon dried dill<br/>
</p>
<h3>Directions:</h3>
<ol>
          <li>Brown the hamburger.</li>
          <li>Add onions and cook until transparent.</li>
          <li>Add brown sugar and dill.</li>
          <li>Cook and drain pasta.</li>
          <li>Combine meat and pasta.</li>
</ol>

<h2>A balanced breakfast</h2>
<h3>Ingredients:</h3>
<p>
          1 cup cereal<br/>
          1 glass orange juice<br/>
          1 cup milk<br/>
          2 slices toast<br/>
</p>
<h3>Directions:</h3>
<ol>
          <li>Combine cereal and milk in bowl.</li>
          <li>Add all ingredients to table.</li>
</ol>
</body>
</html>

Вы можете отобразить этот результат в браузере, как показано на рисунке 1.

Рисунок 1. Результат, отображенный в браузере
Результат, отображенный в браузере

Как уже упоминалось, конечной целью может быть любой формат, не только XHTML, и даже не обязательно XML.

Давайте начнем с простых преобразований.

Простая таблица стилей

Самая простая таблица стилей - это просто XML документ, включающий XSLT-вывод (см. листинг 3).

Листинг 3. Самая простая таблица стилей
<html xsl:version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns="http://www.w3.org/TR/xhtml1/strict">
  <head>
    <title>Recipe</title>
  </head>
  <body>
    <h2><xsl:value-of 
select="/recipes/recipe/name"/></h2> 
    <h3>Ingredients:</h3>
    <p><xsl:value-of 
select="/recipes/recipe/ingredients"/></p>
    <h3>Directions:</h3>
    <p><xsl:value-of 
select="/recipes/recipe/instructions"/></p>
  </body>
</html>

Обратите внимание на использование пространства имен xsl. Добавление этого пространства имен говорит процессору, какие элементы связаны с обработкой, а какие должны быть просто выведены. Элементы value-of говорят процессору вставить определенные данные в это место. Какие именно данные вставлять определяется содержимым атрибута select.

Атрибут select состоит из выражения XPath. Подробнее XPath будет обсуждаться в разделе Подробнее об XPath, однако здесь вы можете видеть, что доступ к элементам "название", "ингредиенты" и "инструкция по приготовлению" происходит через иерархию документа. Мы начинаем с корневого элемента, /recipes, и от него движемся вниз.

Как выполнить преобразование

Простейший способ выполнить XML-преобразование - это добавить указание на таблицу стилей в XML и отобразить его в браузере (см. листинг 4).

Листинг 4. Добавление в XML инструкции по обработке при помощи таблицы стилей
<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="basicstylesheet.xsl" version="1.0" 
?>
<recipes>
   <recipe>
       <name>Gush'gosh</name>
...

Эта инструкция по обработке говорит браузеру извлечь таблицу стилей, расположенную в basicstylesheet.xsl, и использовать ее для преобразования XML-данных и вывода результатов. Если вы откроете наш XML-документ в браузере Microsoft® Internet Explorer®, то увидите результат, похожий на рисунок 2.

Рисунок 2. Извлечение таблицы стилей и преобразование XML-данных
Извлечение таблицы стилей и преобразование XML-данных

Однако это не совсем то, что мы хотели получить. Если вы выберете в браузере Вид>Просмотр HTML-кода, то увидите изначальный XML. Чтобы увидеть результат преобразования, необходимо произвести это преобразование и создать выходной файл. Это можно сделать через командную строку, используя Java-код со следующей командой (см. листинг 5):

Листинг 5. Преобразование документа через командную строку
java org.apache.xalan.xslt.Process -IN recipes.xml -XSL basicstylesheet.xsl -out 
result.html

Если вы получите исключение ClassNotFoundException, возможно, вам нужно загрузить Apache Xalan (см. "Получить продукты и технологии" в разделе Ресурсы) и добавить включенные в него JAR-файлы в путь к классам.

Выполнив преобразование, показанное в листинге 5, вы увидите, что файл result.html содержит следующий код (см. листинг 6).

Листинг 6. Результаты
<?xml version="1.0" encoding="UTF-8"?>
<html xmlns="http://www.w3.org/TR/xhtml1/strict">
<head><title>Recipe</title></head>
<body>
<h2>Gush'gosh</h2>
<h3>Ingredients:</h3>
<p>
          1poundhamburger
          1poundelbow macaroni
          2cupsbrown sugar
          1bagchopped onions
          1teaspoondried dill
       </p>
<h3>Directions:</h3>
<p>
          Brown the hamburger.
          Add onions and cook until transparent.
          Add brown sugar and dill.
          Cook and drain pasta.
          Combine meat and pasta.
       </p>
</body></html>

Я добавил несколько интервалов для удобства чтения, однако здесь следует отметить пару моментов. Во-первых, листинг 6 отображает информацию только для одного рецепта. Во-вторых, ингредиенты слеплены вместе без каких-либо пробелов. Это тоже не тот результат, который мы хотели получить. К счастью, можно создать более точные шаблоны для отображения данных именно в той форме, в какой вы хотите.


Добавление шаблонов

От преобразования нет никакой пользы, если оно не приводит данные именно к той форме, которая нам нужна. Чтобы это сделать, нужно уметь использовать шаблоны, чему и посвящен данный раздел.

Создание шаблонов

Большинство таблиц стилей не имеют такой простой формы, какую вы только что видели в предыдущем разделе. Вместо этого они разбиваются на группу шаблонов, каждый из которых применяется к определенному типу данных. Давайте переведем нашу таблицу стилей в эту форму (см. листинг 7).

Листинг 7. Переделанная таблица стилей
<xsl:stylesheet 
      version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns="http://www.w3.org/TR/xhtml1/strict">

<xsl:template match="/">
<html>
  <head>
    <title>Recipe</title>
  </head>
  <body>
    <h2><xsl:value-of select="/recipes/recipe/name"/></h2> 
    <h3>Ingredients:</h3>
    <p><xsl:value-of 
select="/recipes/recipe/ingredients"/></p>
    <h3>Directions:</h3>
    <p><xsl:value-of 
select="/recipes/recipe/instructions"/></p>
  </body>
</html>
</xsl:template></xsl:stylesheet>

Здесь информация не изменилась, за исключением того, что процессор смотрит на таблицу стилей и начинает с шаблона, совпадающего с корневым элементом документа, как указано в атрибуте match. Затем он выводит этот шаблон, включая все значения, так же как и раньше. Если вы выполните сейчас преобразование, то должны увидеть точно такие же результаты, как и в листинге 6.

Но это не то, что мы хотим. Мы хотим иметь возможность форматировать ингредиенты и инструкции. Для этого мы можем создать отдельные шаблоны для каждого из этих элементов и включить их в таблицу стилей (см. листинг 8).

Листинг 8. Создание дополнительных шаблонов
<xsl:stylesheet
      version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns="http://www.w3.org/TR/xhtml1/strict">
   
<xsl:template match="/">
<html>
  <head>
    <title>Recipe</title>
  </head>
  <body>
    <h2><xsl:value-of select="/recipes/recipe/name"/></h2> 
    <h3>Ingredients:</h3>
    <p><xsl:apply-templates 
select="/recipes/recipe/ingredients"/></p>
    <h3>Directions:</h3>
    <p><xsl:apply-templates 
select="/recipes/recipe/instructions"/></p>
  </body>
</html>
</xsl:template>

<xsl:template match="ingredients">

   <h3>INGREDIENTS HERE</h3>

</xsl:template>


<xsl:template match="instructions">

   <h3>INSTRUCTIONS HERE</h3>

</xsl:template>

</xsl:stylesheet>

Обратите внимание, что вместо того, чтобы просто вывести элемент value-of, мы теперь указываем таблице стилей применять соответствующие шаблоны к элементам ingredients и instructions. Затем мы создали отдельные шаблоны для этих элементов, задав их в атрибуте match. Добравшись до элемента apply-templates, процессор выбирает все элементы ingredients в документе. Затем он ищет шаблон для ингредиентов, а, найдя его, выводит этот шаблон. То же самое он делает с элементом instructions. Результат должен быть похож на изображенный на рисунке 3.

Рисунок 3. Применение соответствующих шаблонов к элементам ingredients и instructions
Применение соответствующих шаблонов к элементам ingredients и instructions

Так, это уже немного ближе, хотя бы понятно, что здесь два рецепта, однако вы вряд ли захотите объединять ингредиенты и инструкции для всех рецептов. К счастью, эту проблему можно решить лучшей организацией шаблонов.

Публикация шаблонов

Чтобы лучше организовать данные, обратим внимание на то, как мы разделяем и публикуем шаблоны. XSLT позволяет обрабатывать информацию итеративным образом. Например, можно поделить информацию на отдельные рецепты, а затем отформатировать инструкции и ингредиенты (см. листинг 9).

Листинг 9. Выделение рецептов
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.w3.org/TR/xhtml1/strict">

      <xsl:template match="/">
      <html>
        <head>
          <title>Recipe</title>
        </head>
        <body>
         <xsl:apply-templates select="/recipes/recipe"/>
        </body>
      </html>
      </xsl:template>

    <xsl:template match="recipe">

          <h2><xsl:value-of select="./name"/></h2> 
          <h3>Ingredients:</h3>
          <p><xsl:apply-templates select="./ingredients"/></p>
          <h3>Directions:</h3>
          <p><xsl:apply-templates  
select="./instructions"/></p>

      </xsl:template>
      
      <xsl:template match="ingredients">

         <h3>INGREDIENTS HERE</h3>

      </xsl:template>


      <xsl:template match="instructions">

         <h3>INSTRUCTIONS HERE</h3>

      </xsl:template>

      </xsl:stylesheet>

В данном случае таблица стилей выводит основную страницу (HTML), а затем просматривает каждый рецепт, выводя название, ингредиенты и инструкции для каждого рецепта. Опять-таки XPath мы будем изучать в разделе Подробнее об XPath, но в данном случае элемент recipe становится контекстным узлом, поэтому атрибуты select относятся к этому узлу так же как файлы к конкретному каталогу в файловой системе. Результат должен быть похож на рисунок 4.

Рисунок 4. Элемент recipe становится контекстным узлом
Элемент recipe становится контекстным узлом

Отлично, формат приблизился к желаемому, однако нам все еще нужно отобразить фактическую информацию. Для этого надо изменить шаблоны ingredients и instructions (см. листинг 10).

Листинг 10. Работа над шаблонами ingredients и instructions
...
    <xsl:template match="recipe">

          <h2><xsl:value-of select="./name"/></h2> 
          <h3>Ingredients:</h3>
          <p><xsl:apply-templates select="./ingredients"/></p>
          <h3>Directions:</h3>
          <ol><xsl:apply-templates  
select="./instructions"/></ol>

      </xsl:template>

      <xsl:template match="ingredients/ingredient">

         <xsl:value-of select="./qty"/> <xsl:value-of 
select="./unit"/> <xsl:value-of select="./food"/><br />

      </xsl:template>


      <xsl:template match="instructions/instruction">

         <li><xsl:value-of select="."/></li>

      </xsl:template>

      </xsl:stylesheet>

Важный момент при публикации шаблонов: вы указали процессору применять подходящие шаблоны к элементу ingredients, однако у нас нет специального шаблона для этого элемента. Если вы примените шаблон к элементу, а самого шаблона не будет, то данные просто не появятся. Но это не наш случай.

Наоборот, мы воспользовались тем, что когда указали процессору применять подходящие шаблоны к элементу ingredients, он ищет не только элемент ingredients, но и дочерние элементы элемента ingredients. Таким образом, он находит шаблон для ингредиентов, в котором вы выводите количество, единицы измерения, название продукта и разрыв строки.

То же самое мы сделали для инструкций, когда отформатировали их как элементы списка. Заметьте, что мы создали фактически упорядоченный список в основном шаблоне для рецепта, а затем отправили элементы для индивидуальной обработки.

Результат должен быть похож на рисунок 5.

Рисунок 5. Создание упорядоченного списка в основном шаблоне рецепта
Создание упорядоченного списка в основном шаблоне рецепта

Определенно формат приближается к желаемому. Однако если вы посмотрите на вывод, то увидите, что проблема с пробелами все еще существует (см. листинг 11).

Листинг 11. Недоработанный вывод
<?xml version="1.0" encoding="UTF-8"?>
<html 
xmlns="http://www.w3.org/TR/xhtml1/strict"><head><title>Recipe
</title></head><body><h2>Gush'gosh</h2><h3>
Ingredients:</h3><p>
          1poundhamburger<br/>
          1poundelbow macaroni<br/>
          2cupsbrown sugar<br/>
          1bagchopped onions<br/>
          1teaspoondried dill<br/>
       </p><h3>Directions:</h3><ol>
          <li>Brown the hamburger.</li>
          <li>Add onions and cook until transparent.</li>
...

Добавление пробелов

Почему это случилось, если мы включали пробелы в таблицу стилей? Должны они были появиться в выводе? Разумеется, необязательно. Есть способы указать таблице стилей оставлять пробелы - они будут изучены в разделе Организация циклов и импорт - однако в некоторых случаях проще явно добавить текст в вывод (см. листинг 12).

Листинг 12. Добавление текста
...
      <xsl:template match="ingredients/ingredient">

         <xsl:value-of select="./qty"/><xsl:text> 
</xsl:text>
         <xsl:value-of select="./unit"/><xsl:text> 
</xsl:text>
         <xsl:value-of select="./food"/><br />

      </xsl:template>
...

Тем самым мы позаботились о недостающих пробелах. Точно так же с помощью элемента text, можно добавить в шаблон любой произвольный текст. (Помните, что только текст, а не элементы типа разрыва страницы.) Результатом будет такой вывод, какой нам нужен (см. листинг 13).

Листинг 13. Окончательный вывод
<?xml version="1.0" encoding="UTF-8"?>
<html 
xmlns="http://www.w3.org/TR/xhtml1/strict"><head><title>Recipe
</title></head><body><h2>Gush'gosh</h2><h3>
Ingredients:</h3><p>
          1 pound hamburger<br/>
          1 pound elbow macaroni<br/>
          2 cups brown sugar<br/>
          1 bag chopped onions<br/>
          1 teaspoon dried dill<br/>
       </p><h3>Directions:</h3><ol>
          <li>Brown the hamburger.</li>
          <li>Add onions and cook until transparent.</li>
          <li>Add brown sugar and dill.</li>
          <li>Cook and drain pasta.</li>
          <li>Combine meat and pasta.</li>
       </ol><h2>A balanced
 breakfast</h2><h3>Ingredients:</h3><p>
          1 cup cereal<br/>
          1 glass orange juice<br/>
          1 cup milk<br/>
          2 slices toast<br/>
       </p><h3>Directions:</h3><ol>
          <li>Combine cereal and milk in bowl.</li>
          <li>Add all ingredients to table.</li>
       </ol></body></html>

Результат показан на рисунке 6.

Рисунок 6. Проблема отсутствующих пробелов решена
Проблема отсутствующих пробелов решена

Далее вы узнаете, как добавлять на страницу определенную информацию с помощью XPath.


Основы XPath

Возможность преобразовывать данные в форму, в какой вы желаете их видеть, требует понимания языка маршрутов XML, или XPath, который позволяет контролировать, какие именно данные публикуются и/или отображаются. Данный раздел объясняет основные понятия XPath и показывает, как создавать простые выражения.

Что такое XPath?

Вы должны были заметить, что важной частью функционирования таблицы стилей является возможность выбрать конкретную часть документа. Например, если вы хотите отобразить инструкции, то нужно знать, как на них ссылаться. В XSLT мы ссылаемся на информацию, используя выражения XPath.

Выражение XPath может выбрать единственный узел или набор узлов, либо вернуть единственное значение, основанное на одном или более узлов в документе. До сих пор мы имели дело с очень простыми выражениями XPath, которые выбирают узел или узлы, спускаясь вниз по иерархической структуре. XPath предоставляет несколько способов для задания групп узлов на основании отношений, таких как родитель-потомок или предок-потомок. В данном руководстве мы изучим все эти отношения, называемые осями.

Вы также узнаете о некоторых более мощных функциях XPath и о предикатах - это в основном условные утверждения, которые можно добавлять в выражения. Например, в разделе Настройка контекста вы увидите, как выбирать все элементы recipe в документе; предикаты позволяют выбрать только конкретный элемент на основании конкретных критериев.

Наконец, вы узнаете о еще более мощных функциях, которые позволяют использовать многие типы логики, которые используются в процедурных программах.

Давайте начнем с изучения контекста выражения.

Настройка контекста

Первым шагом в понимании XPath является понимание того, что полученные результаты в большой степени определяются текущим контекстным узлом. Контекстный узел можно считать своеобразным знаком "ты находишься здесь", от которого можно двигаться в различных направлениях согласно выражению XPath. Например, рассмотрим простую таблицу стилей в листинге 14.

Листинг 14. Демонстрация контекста
    <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:template match="/">

        <xsl:copy-of select="." />

        </xsl:template>


    </xsl:stylesheet>

Здесь есть новый элемент - copy-of. Там, где value-of выводит содержимое элемента, copy-of делает именно то, о чем говорит его название, и выводит фактический узел, на который ссылается атрибут select.

В данном случае в атрибуте select содержится одно из простейших возможных выражений XPath. Одиночная точка (.) – это ссылка на данный контекстный узел, как в файловой системе, когда вы хотите сослаться на "текущую директорию, вне зависимости от того, что это за директория." Поэтому если вы выполните это преобразование, то получите результат, как в листинге 15.

Листинг 15. Простейшее преобразование
        <recipes>
        <recipe recipeId="1">
        <name>Gush'gosh</name>
        <ingredients>

        <ingredient><qty>1</qty><unit>pound</unit>
        <food>hamburger </food></ingredient>

        <ingredient><qty>1</qty><unit>pound</unit>
        <food>elbow macaroni</food></ingredient>

        <ingredient><qty>2</qty><unit>cups</unit>
        <food>brown sugar</food></ingredient>

        <ingredient><qty>1</qty><unit>bag</unit>
    <food>chopped onions</food></ingredient>

        <ingredient><qty>1</qty><unit>teaspoon</unit>
        <food>dried dill</food></ingredient>
        </ingredients>
        <instructions>
        <instruction>Brown the hamburger.</instruction>
        <instruction>Add onions and cook until transparent.</instruction>
        <instruction>Add brown sugar and dill.</instruction>
        <instruction>Cook and drain pasta.</instruction>
        <instruction>Combine meat and pasta.</instruction>
        </instructions>
        </recipe>
        ...
        </recipes>

Вы видите, что это просто повторение того же документа; это потому, что контекстный узел, как указано атрибутом шаблона match, - это корень документа, или /. Если вы измените контекстный узел, вывод изменится. Например, вы можете установить контекстный узел на первый рецепт (см. листинг 16).

Листинг 16. Перемещение контекстного узла
		<xsl:stylesheet version="1.0"
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
		xmlns="http://www.w3.org/TR/xhtml1/strict">

		<xsl:template match="/recipes/recipe">

		<xsl:copy-of select="." />

		</xsl:template>


		</xsl:stylesheet>

Теперь, запустив преобразование, вы увидите разницу (см. листинг 17).

Листинг 17. Результаты
        <?xml version="1.0" encoding="UTF-8"?>

        <recipe recipeId="1">
        <name>Gush'gosh</name>
        <ingredients>

        <ingredient><qty>1</qty><unit>pound</unit>
        <food>hamburger</food></ingredient>

        <ingredient><qty>1</qty><unit>pound</unit>
        <food>elbow macaroni</food></ingredient>

        <ingredient><qty>2</qty><unit>cups</unit>
        <food>brown sugar</food></ingredient>

        <ingredient><qty>1</qty><unit>bag</unit>
        <food>chopped onions</food></ingredient>

        <ingredient><qty>1</qty><unit>teaspoon</unit>
        <food>dried dill</food></ingredient>
        </ingredients>
        <instructions>
        <instruction>Brown the hamburger.</instruction>
        <instruction>Add onions and cook until transparent.</instruction>
        <instruction>Add brown sugar and dill.</instruction>
        <instruction>Cook and drain pasta.</instruction>
        <instruction>Combine meat and pasta.</instruction>
        </instructions>
        </recipe>

        <recipe recipeId="2">
        <name>A balanced breakfast</name>
        <ingredients>

        <ingredient><qty>1</qty><unit>cup</unit>
        <food>cereal</food></ingredient>

        <ingredient><qty>1</qty><unit>glass</unit>
        <food>orange juice</food></ingredient>

        <ingredient><qty>1</qty><unit>cup</unit>
        <food>milk</food></ingredient>

        <ingredient><qty>2</qty><unit>slices</unit>
        <food>toast</food></ingredient>
        </ingredients>
        <instructions>
        <instruction>Combine cereal and milk in bowl.</instruction>
        <instruction>Add all ingredients to table.</instruction>
        </instructions>
        </recipe>

Так как мы переместили контекстный узел, вывод изменился. Это важно, когда вы хотите выбрать узел относительно контекстного узла. Например, вы можете выбрать только заголовок рецепта (см. листинг 18).

Листинг 18. Выбор только заголовка
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:template match="/recipes/recipe">

        <xsl:copy-of select="./name" />

        </xsl:template>


        </xsl:stylesheet>

Здесь вы выбираете элемент name, расположенный на один уровень ниже, чем текущий контекстный узел, поэтому результат будет как в листинге 19.

Листинг 19. Результаты
        <?xml version="1.0" encoding="UTF-8"?>
        <name>Gush'gosh</name>
        <name>A balanced breakfast</name>

Мы изучим задание узлов по номеру позже, а пока отметим, что мы можем переместить контекстный узел во второй рецепт (см. листинг 20).

Листинг 20. Еще одно перемещение контекстного узла
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:template match="/recipes/recipe">
        </xsl:template>

        <xsl:template match="/recipes/recipe[2]">

        <xsl:copy-of select="./name" />

        </xsl:template>


        </xsl:stylesheet>

(Не обращайте внимания на еще один шаблон, он нужен, чтобы не появлялся текст другого рецепта.)

Мы можем видеть, что результирующее преобразование показывает это изменение контекста (см. листинг 21).

Листинг 21. Результаты
        <?xml version="1.0" encoding="UTF-8"?>
        <name>A balanced breakfast</name>

Для чего нужны оси

Теперь, когда мы знаем, откуда мы начинаем, было бы полезно узнать, куда можно двигаться. До сих пор мы использовали очень простые выражения XPath, похожие на иерархию в файловой системе, однако XPath предоставляет гораздо больше возможностей. Например, до сих пор вы выбирали только дочерние элементы, однако вы можете также искать родителей конкретного узла, а также его потомков или предков.

Для начала давайте поговорим о системе обозначений. Мы использовали упрощенную, укороченную форму запроса потомков. В "длинной форме" выражения задаются как child::name вместо ./name

В обоих случаях вы задаете любой узел, который является потомком контекстного узла, а также является элементом name. Вы также можете связать их вместе, как в предыдущем случае, используя /child::recipes/child::recipe вместо /recipes/recipe.

Потомки

Возможно, вы недоумеваете, зачем мучаться с длинной формой, если короткая настолько проще. Это не было бы нужно, если бы единственное, что вы могли бы делать - это выбор потомков. Однако эту нотацию также можно использовать для выбора других отношений. Например, выражение XPath descendant::instruction выбирает все элементы instruction, которые являются потомками контекстного узла, а не только дочерние элементы. Кроме того, можно комбинировать инструкции. Например, вы можете выбрать все инструкции второго рецепта: /recipes/recipe[2]/descendant::instruction.

Одной из разновидностей оси потомков является ось потомок-или-сам-элемент, которая выбирает заданный узел из всех потомков, а также ищет в самом контекстном узле. Например, выражение descendant-or-self::instructions выбирает все узлы instruction в контекстном узле и ниже его. Обычным сокращением для этой оси является двойная косая черта, //. Это означает, что выражения: /recipes/recipe[2]//instructions и //instructions выбирают все инструкции для второго рецепта и все инструкции в документе, соответственно. Этот второй пример очень широко применяется, он удобен, когда вы хотите просто выбрать все элементы определенного типа в документе.

Атрибуты

Еще одна общая задача, с которой вы столкнетесь - это необходимость выбрать атрибут для конкретного элемента. Например, вы, возможно, захотите выбрать recipeId для конкретного рецепта. Выражение /recipes/recipe/attribute::recipeId выбирает атрибут recipeId для всех элементов recipe. Эта ось также имеет сокращенную форму: это же выражение можно записать так: /recipes/recipe/@recipeId.

Родители

Все, что мы видели до этого, переносило нас вниз по дереву иерархии, но также существует возможность пойти вверх, выбрав предка конкретного узла. Предположим, что контекстным узлом была одна из инструкций, а вы хотите вывести recipeId для текущего рецепта. Вы можете сделать это следующим образом: ./parent::node()/parent::node()/@recipeId.

Это выражение начинается в текущем узле - instruction -, а затем двигается к предку этого узла - элементу instructions - а затем к предку ТОГО элемента - recipe -, а затем к соответствующему атрибуту. Возможно, вам лучше знакома сокращенная форма: ./../../@recipeId.

Теперь давайте посмотрим, как задаются некоторые условия.


Более продвинутые возможности XPath

В большинстве случаев уже рассмотренных приемов достаточно. Однако нередко встречаются ситуации, требующие большей избирательности. Данный раздел показывает, как использовать предикаты для выбора узлов, основанных на конкретных критериях, и дает представление о некоторых функциях, встроенных в XPath.

Использование предикатов

Зачастую требуется не просто любой узел, а конкретный узел, выбранный на основе конкретных условий. Вы ранее уже видели пример, когда использовали выражение /recipes/recipe[2]//instructions. Это на самом деле сокращенная версия выражения /recipes/recipe[position() = 2]//instructions, которое означает, что процессор XPath должен пройти через каждый элемент recipes (конечно, такой элемент только один) и для каждого элемента recipes пройти через каждый элемент recipe. Для каждого элемента recipe проверить истинность выражения position() = 2. (Другими словами, есть ли в списке этот второй рецепт?) Если это предложение, называемое предикатом, истинно, то процессор использует этот узел и продолжает, возвращая любые инструкции.

С помощью предикатов можно сделать множество вещей. Например, можно вернуть только рецепты, в которых есть название: /recipes/recipe[name]. Это выражение просто проверяет, существует ли элемент name - потомок элемента recipe. Также можно поискать конкретные значения. Например, можно возвращать только элементы, которые называются "A balanced breakfast": //recipe[name="A balanced breakfast"].

Имейте в виду, что предикат просто говорит процессору, возвращать ли текущий узел, поэтому в данном случае возвращается элемент recipe, а не имя. С другой стороны, можно указать процессору возвратить только название первого рецепта при помощи любого и этих двух выражений (см. листинг 22).

Листинг 22. Возвращение только названия первого рецепта
        //recipe[@recipeId='1']/name
        //name[parent::recipe[@recipeId='1']]

В первом выражении сначала мы выбираем все элементы recipe, а затем возвращаем только тот, у которого есть атрибут элемента recipeId, равный 1. Найдя этот узел, мы двигаемся к его дочернему узлу, который называется name, и возвращаем его. Во втором выражении сначала отыскиваются все элементы name, а затем выбирается только тот, у чьего родителя имеется атрибут 1. В любом случае, вы получите один и тот же вывод (см. листинг 23).

Листинг 23. Вывод
        <?xml version="1.0" encoding="UTF-8"?>
        <name>Gush'gosh</name>

Функции

XPath также предоставляет ряд функций. Некоторые из них относятся собственно к узлам, - например, те, которые ищут конкретную позицию, - некоторые обрабатывают строки, некоторые , - такие как суммирование, - с числами, некоторые с булевскими значениями.

Функции, связанные с узлами

Функции, связанные с узлами, помогают, например, выбрать конкретный узел в зависимости от позиции. Например, вы можете специально запросить последний рецепт: //recipe[last()]. Данное выражение выбирает все элементы recipe, а затем возвращает только последний. Вы также можете использовать функции отдельно, вместо того чтобы использовать их как часть предиката. Например, вы можете специально запросить посчитать элементы recipe: count(//recipe).

Вы уже видели функцию position() и то, как она работает. Другие функции, связанные с узлами, включают id(), local-name(), namespace-uri() и name().

Строковые функции

Большинство строковых функций предназначено для обработки строк, а не для их проверки, за исключением функции contains(). Функция contains() показывает, является ли данная строка частью большего целого. Это позволит, например, вернуть только узлы, содержащие определенные строки, такие как: //recipe[contains(name, 'breakfast')].

Это выражение возвращает элемент recipe, который содержит в своем элементе name строку "breakfast".

Функция substring() позволяет выбрать конкретный диапазон символов из строки. Например, выражение: substring(//recipe[2]/name, 1, 5) возвращает A bal.

Первый аргумент - это полная строка, второй - позиция первого символа, а третий - это длина диапазона.

Среди прочих строковых функций имеются: concat(), substring-before(), substring-after(), starts-with() и string-length().

Числовые функции

Числовые функции включают функцию number(), которая переводит значение в числовое, чтобы другие функции могли с ним работать. Числовые функции также включают: sum(), floor(), ceiling() и round(). Например, вы можете найти сумму всех значений recipeId при помощи выражения: sum(//recipe/@recipeId).

Конечно, особого повода проводить подобное вычисление нет, однако это просто числовое значение, приведенное для примера.

Функция floor() находит наибольшее целое, которое меньше или равно данному значению, а функция ceiling() находит наименьшее целое, которое больше или равно данному значению. Функция round() работает традиционным образом - округляет (см. листинг 24).

Листинг 24. Результаты числовых функций
        floor(42.7) = 42
        ceiling(42.7) = 43
        round(42.7) = 43

Булевы функции

Булевы функции наиболее полезны при работе с условными выражениями, о которых будет рассказано в разделе Условная обработка. Возможно, наиболее полезной функцией является not(), которая может быть использована для определения того, что определенный узел не существует. Например, выражение //recipe[contains(name, 'breakfast')] возвращает каждый рецепт, содержащий в элементе name строку "breakfast". Но что, если вам нужны все рецепты, кроме завтрака? Можно использовать выражение: //recipe[not(contains(name, 'breakfast'))].

Другие булевы функции включают true() и false(), которые возвращают константы, и boolean(), которая преобразует значение в булево, чтобы его можно было использовать в качестве проверочного.


Организация циклов и импорт

Рассмотрим еще два важных аспекта использования таблиц стилей XSLT: создание циклов и импортирование внешних таблиц стилей.

Организация циклов

При работе с XSLT необходимо привыкнуть к тому, что это функциональный язык, а не процедурный. Другими словами, обычно вы явно не контролируете способ, которым он выполняет данные ему инструкции. Однако существуют исключения. Например, существует возможность организовывать циклы и выполнять условные операции. Давайте начнем с циклов.

В предшествующем примере мы использовали выражения XSLT, встроенные в шаблон публикации, чтобы применить стиль к конкретным элементам. В некоторых случаях это отлично работает. Однако в ситуации, когда имеются сложные XML файлы или сложные требования, иногда проще обратиться к информации явно (см. листинг 25).

Листинг 25. Прямое применение стилей с использованием циклов
        <xsl:template match="recipe">

        <h2><xsl:value-of select="./name"/></h2>
        <h3>Ingredients:</h3>
        <p>
        
            <xsl:for-each select="./ingredients/ingredient">
            <xsl:value-of select="./qty"/><xsl:text> </xsl:text>
            <xsl:value-of select="./unit"/><xsl:text> </xsl:text>
            <xsl:value-of select="./food"/><br />
            </xsl:for-each>

        </p>

        <h3>Directions:</h3>
        <ol>

            <xsl:for-each select="./instructions/instruction">
            <li><xsl:value-of select="."/></li>
            </xsl:for-each>

        </ol>

        </xsl:template>

        </xsl:stylesheet>

Конструкция цикла очень похожа на структуру for-each, в честь которой она названа. Подобно тезке, каждый экземпляр цикла несет в себе следующее значение списка. В Java-программировании это могло бы быть следующее значение в массиве; здесь это следующий узел в совокупности узлов, возвращенных выражением XPath в атрибуте select. Это означает, что когда вы первый раз выполняете первый цикл, контекстным узлом является первый элемент ingredient. Это позволяет выбрать потомков этого элемента qty, unit и food и добавить их в документ так же, как это было сделано ранее при помощи шаблона. То же самое и с инструкциями, за исключением того, что они просто выводятся напрямую.

Результаты идентичны тем, что получаются при публикации через шаблоны - почти. Каждый шаблон добавляется к документу как индивидуальная строка, но так как нам необходимо обрабатывать эту информацию как один шаблон, мы теряем множество пробелов, которые видели раньше (см. рисунок 7).

Рисунок 7. Результаты
Результаты

Для некоторых XML-приложений это имеет значение, но здесь мы используем HTML, поэтому это значения не имеет. Однако помните об этом, когда решаете, какой метод использовать.

Включение и импорт таблиц стилей

Другая вариация таблиц стилей касается их структуры. До сих пор вся наша информация хранилась в единственной таблице стилей. Однако в некоторых случаях бывает полезно разбить ее на отдельные таблицы стилей. Такая модульность может облегчить поддержку, а также гибкость, позволяя использовать различные таблицы стилей для различных целей. Например, мы можем создать две различные таблицы стилей, одна из которых будет использоваться для ингредиентов (см. листинг 26).

Листинг 26. Файл ingredients.xsl
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:template match="ingredients/ingredient">

        <xsl:value-of select="./qty"/><xsl:text> </xsl:text>
        <xsl:value-of select="./unit"/><xsl:text> </xsl:text>
        <xsl:value-of select="./food"/><br />

        </xsl:template>

        </xsl:stylesheet>

Также можно создать отдельную таблицу стилей для инструкций (см. листинг 27).

Листинг 27. Файл instructions.xsl
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:template match="instructions/instruction">

        <li><xsl:value-of select="."/></li>

        </xsl:template>

        </xsl:stylesheet>

Эти шаблоны идентичны шаблонам из действующей таблицы стилей. Их можно добавить к таблице стилей посредством включения (см. листинг 28).

Листинг 28. Включение таблиц стилей
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        
            <xsl:include href="ingredients.xsl" />
            <xsl:include href="instructions.xsl" />
        

        <xsl:template match="/">
        ...
        </xsl:template>

        <xsl:template match="recipe">

        <h2><xsl:value-of select="./name"/></h2>
        <h3>Ingredients:</h3>
        <p><xsl:apply-templates select="./ingredients"/></p>
        <h3>Directions:</h3>
        <ol><xsl:apply-templates  
select="./instructions"/></ol>

        </xsl:template>

        </xsl:stylesheet>

Хотя здесь мы разместили таблицы стилей в той же директории, что и основную таблицу, делать это не обязательно: атрибут href может содержать любой доступный URL. Обратите внимание, что мы отсылаем процессор на поиск шаблонов для элементов ingredients и instructions, которых нет в этом файле. Однако если обработать таблицу стилей, результат получится точно тот же, как если бы шаблоны были включены напрямую, а не через элемент include (см. рисунок 8).

Рисунок 8. Результаты
Результаты

Элемент include дает тот же результат, как если бы мы добавили содержимое начиная с данной точки. Семантически они идентичны. С другой стороны, есть еще один способ включения информации - импорт.

XSLT позволяет импортировать таблицу стилей в начало файла. Почему в начало? Потому что целью импорта таблицы стилей является возможность корректировки любых шаблонов, являющихся частью импорта. Например, мы можем импортировать шаблон ingredients и откорректировать его (см. листинг 29).

Листинг 29. Импорт таблицы стилей
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict">

        <xsl:import href="ingredients.xsl" />
        <xsl:import href="instructions.xsl" />

        <xsl:template match="/">
        ...
        </xsl:template>

        <xsl:template match="recipe">
        ...
        </xsl:template>

        
            <xsl:template match="ingredients">

            <ul><xsl:apply-templates select="./ingredient" /></ul>

            </xsl:template>

            <xsl:template match="ingredient">

            <li><xsl:value-of select="./qty"/><xsl:text> 
</xsl:text>
            <xsl:value-of select="./unit"/>
            <xsl:text> </xsl:text><xsl:value-of
            select="./food"/></li>

            </xsl:template>
        

        </xsl:stylesheet>

Здесь мы фактически заменили один шаблон двумя, которые заменяют шаблоны в импортированной таблице стилей (см. рисунок 9).

Рисунок 9. Результаты
Результаты

Обратите внимание, что, так как иерархия зависит от расположения, того же результата можно было бы добиться и с помощью включения. Однако XSLT позволяет использовать атрибут priority, чтобы задать приоритет шаблонов при обработке импорта.

Расширение XSLT

Мы увидели, как сделать XSLT более похожим на программирование. Как насчет добавления к нему фактического программирования? Давайте взглянем на добавление функциональности Java к таблице стилей XSLT.

Во-первых, следует отметить, что хотя механизм расширения является частью рекомендаций XSLT, рассматриваемая здесь реализация специфична для процессора Xalan XSLT. Основные идеи практически одинаковы для других процессоров, однако для уточнения деталей вам придется сверяться с документацией.

Далее мы создадим расширение, которое позволит нам масштабировать рецепт на несколько порций.

Элементы расширения

Расширение XSLT производится с помощью различных методик. Первая - это использование элементов extension. Элемент extension - это элемент в пространстве имен, который указывает на класс Java. Взгляните, например, на следующий элемент extension (см. листинг 30).

Листинг 30. Использование элемента extension
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict"
        
            xmlns:scaler = "com.backstop.RecipeScaler"
            extension-element-prefixes="scaler">
        

        <xsl:template match="/">
        <html>
        <head>
        <title>Recipes</title>
        </head>
        <body>

        <scaler:scaleMessage servings="2" />

        <xsl:apply-templates select="/recipes/recipe"/>
        </body>
        </html>
        </xsl:template>
        ...

Мы создали пространство имен, которое соответствует классу comp.backstop.RecipeScaler, который включает в себя статический метод под названием scaleMessage (см. листинг 31).

Листинг 31. Класс RecipeScaler
        package com.backstop;

        public class RecipeScaler {

        public static String scaleMessage (
        org.apache.xalan.extensions.XSLProcessorContext context,
        org.w3c.dom.Element thisElement){

        return "This recipe has been scaled by a factor of " +
        thisElement.getAttribute("servings") + ".";

        }

        }

Добравшись до элемента, процессор видит префикс пространства имен scaler: и знает, что он обозначен как префикс элемента extension, и таким образом понимает, какой класс обозначен в определении пространства имен. Вызываемый им метод отвечает локальному имени элемента - scaleMessage. Сам метод получает два аргумента, из которых мы фактически используем один. Параметр context ссылается на контекст процессора, который позволяет взглянуть на элементы, относящиеся к элементу extension, однако мы просто займемся самим элементом extension. Так как мы получаем этот элемент как параметр метода, мы можем извлечь значения любых атрибутов, добавленных к этому элементу, таких как servings в данном случае. Текст, возвращенный методом, добавляется к выводу на месте элемента extension.

Это означает, что если применить таблицу стилей, мы получим результаты, показанные на рисунке 10.

Рисунок 10. Результаты элемента extension
Результаты элемента extension

Элементы extension могут быть весьма полезны, хотя и несколько сложны в использовании.

Функции extension

Еще один способ добавить функциональность при помощи таблиц стилей - это использование функций extension, которые несколько проще реализовывать, чем элементы extension. Например, мы можем создать функцию, которая умножает количество ингредиентов и количество порций (см. листинг 32).

Листинг 32. Метод scaleIngredient()
        package com.backstop;

        public class RecipeScaler {

        public static String scaleMessage (
        org.apache.xalan.extensions.XSLProcessorContext context,
        org.w3c.dom.Element thisElement){

        return "This recipe has been scaled by a factor of " +
        thisElement.getAttribute("servings") + ".";

        }

        public static int scaleIngredient(int servings, int original){

        return (servings * original);

        }

        }

Добавление этой функции в таблицу стилей идентично добавлению элемента extension, в котором уже есть карта пространства имен для класса (см. листинг 33).

Листинг 33. Добавление функции extension
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict"
        xmlns:scaler = "com.backstop.RecipeScaler"
        extension-element-prefixes="scaler">
        ...
        <xsl:template match="ingredients/ingredient">

        <xsl:value-of select="scaler:scaleIngredient(2, ./qty)"/>
        <xsl:text> </xsl:text><xsl:value-of select="./unit"/>
        <xsl:text> </xsl:text><xsl:value-of select="./food"/><br
        />

        </xsl:template>
        ...

Учтите, что вызов функции включает префикс пространства имен. Как и ранее, процессор видит префикс и знает, что надо выполнить вызов класса RecipeScaler. В результате количество ингредиентов умножается на два (см. рисунок 11).

Рисунок 11. Использование функции extension
Использование функции extension

Хотя данный код и работает, поддерживать его сложно. Давайте посмотрим, как упростить поддержку.


Программирование XSLT

Прежде, чем закончить изложение, рассмотрим два аспекта XSLT, которые предоставляют некоторые возможности, характерные для обычных языков программирования.

Переменные XSLT

Прекрасно, что мы можем выполнить функцию, но дело кончилось константой, запрятанной в глубине таблицы стилей. Не лучше ли было бы задавать переменные в начале страницы? Конечно, да (см. листинг 34).

Листинг 34. Задание переменной
    <xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.w3.org/TR/xhtml1/strict"
    xmlns:scaler = "com.backstop.RecipeScaler"
    extension-element-prefixes="scaler">

    <xsl:variable name="numberOfServings" select="3" />

    <xsl:template match="/">
    <html>
    <head>
    <title>Recipes</title>
    </head>
    <body>

    <scaler:scaleMessage servings="$numberOfServings" />

    <xsl:apply-templates select="/recipes/recipe"/>
    </body>
    </html>
    </xsl:template>

    <xsl:template match="recipe">
    ...
    </xsl:template>

    <xsl:template match="ingredients/ingredient">

    <xsl:value-of select="scaler:scaleIngredient($numberOfServings,
    ./qty)"/>
    <xsl:text> </xsl:text><xsl:value-of select="./unit"/>
    <xsl:text> </xsl:text><xsl:value-of select="./food"/><br
    />

    </xsl:template>
    ...

XSLT позволяет создавать переменные; в ссылке используется знак доллара ($), который можно увидеть в листинге. Если применить таблицу стилей, можно увидеть два эффекта (см. рисунок 12).

Рисунок 12. Использование переменной
Использование переменной

Обратите внимание, что ингредиенты были умножены на количество порций, как и ожидалось. Однако если вы посмотрите внимательнее, то увидите, что элемент extension сработал неверно, приняв переменную за строку, вместо того чтобы использовать значение самой переменной. Это не сбой; спецификация не требует, чтобы процессор что-либо делал со значениями атрибутов перед обработкой элемента extension. Поэтому нам надо как-то избежать этой проблемы.

Условная обработка

Первое, что мы можем сделать - это использовать условную обработку, чтобы сообщение отображалось, только если оно нужно. Например, см. листинг 35.

Листинг 35. Использование элемента if
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict"
        xmlns:scaler = "com.backstop.RecipeScaler"
        extension-element-prefixes="scaler">

        <xsl:variable name="numberOfServings" select="1" />

        <xsl:template match="/">

        <html>
        <head>
        <title>Recipes</title>
        </head>
        <body>

        <xsl:if test="$numberOfServings > 1">

        <scaler:scaleMessage servings="3" />

        </xsl:if>

        <xsl:apply-templates select="/recipes/recipe"/>
        </body>
        </html>
        </xsl:template>
        ...

Содержимое элемента if, заданное атрибутом test, должно быть равно true (истина). Если это не так, что и произошло в данном случае, вывод не появится вовсе (см. рисунок 13).

Рисунок 13. Результаты предложения if
Результаты предложения if

В том виде, в каком оно написано, предложение не имеет особого смысла; если значение больше единицы, элемент extention отобразится со значением "3." Лучше использовать множественный выбор (см. листинг 36).

Листинг 36. Элемент choose
        <xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns="http://www.w3.org/TR/xhtml1/strict"
        xmlns:scaler = "com.backstop.RecipeScaler"
        extension-element-prefixes="scaler">

        <xsl:variable name="numberOfServings" select="3" />

        <xsl:template match="/">

        <html>
        <head>
        <title>Recipes</title>
        </head>
        <body>

        
            <xsl:choose>
            <xsl:when test="$numberOfServings < 1">
            Recipes have been scaled by an invalid number.
            </xsl:when>
            <xsl:when test="$numberOfServings = 1">
            </xsl:when>
            <xsl:when test="$numberOfServings = 2">
            <scaler:scaleMessage servings="2" />
            </xsl:when>
            <xsl:when test="$numberOfServings = 3">
        
        <scaler:scaleMessage servings="3" />
        
            </xsl:when>
            <xsl:otherwise>
            Recipes have been scaled for multiple portions.
            </xsl:otherwise>
            </xsl:choose>
        

        <xsl:apply-templates select="/recipes/recipe"/>
        </body>
        </html>
        </xsl:template>
        ...

В данном случае у нас имеется комбинация элементов if-then-else и предложения case из традиционных языков программирования. Элемент choose работает как контейнер, однако элемент when отображает его содержимое, только если его атрибут test равен true (истина). Наконец, если ни один из элементов when не равен true (истина), процессор отображает содержимое элемента otherwise.

Результат получается такой, какого следует ожидать (см. рисунок 14).

Рисунок 14. Результат
Результат

Теперь вы можете более гибко задать отображение большего количества порций, или подстроиться под другие условия.


Заключение

Подведение итогов

Данное руководство позволило продвинуться от начального знакомства с преобразованиями XSLT до составления достаточно сложных таблиц стилей. Сначала вы познакомились с основами таблиц стилей, затем с выражениями XPath - одной из основ XSLT. В последней части данного руководства были рассмотрены некоторые более сложные аспекты таблиц стилей XSLT - переменные, условная обработка и расширения. В результате у вас теперь должно быть достаточно знаний, чтобы делать с таблицами стилей XSLT практически все необходимое - или хотя бы понимать, что еще надо выяснить, если столкнетесь с проблемой.

Ресурсы

Научиться

Получить продукты и технологии

  • Apache Xalan: загрузите Xalan и добавьте включенные JAR-файлы в свой путь к классу, чтобы следовать примерам руководства.(EN)
  • Ознакомительное программное обеспечение IBM: ознакомительного программного обеспечения, которое можно загрузить непосредственно с developerWorks.(EN)

Обсудить

Комментарии

developerWorks: Войти

Обязательные поля отмечены звездочкой (*).


Нужен IBM ID?
Забыли Ваш IBM ID?


Забыли Ваш пароль?
Изменить пароль

Нажимая Отправить, Вы принимаете Условия использования developerWorks.

 


Профиль создается, когда вы первый раз заходите в developerWorks. Информация в вашем профиле (имя, страна / регион, название компании) отображается для всех пользователей и будет сопровождать любой опубликованный вами контент пока вы специально не укажите скрыть название вашей компании. Вы можете обновить ваш IBM аккаунт в любое время.

Вся введенная информация защищена.

Выберите имя, которое будет отображаться на экране



При первом входе в developerWorks для Вас будет создан профиль и Вам нужно будет выбрать Отображаемое имя. Оно будет выводиться рядом с контентом, опубликованным Вами в developerWorks.

Отображаемое имя должно иметь длину от 3 символов до 31 символа. Ваше Имя в системе должно быть уникальным. В качестве имени по соображениям приватности нельзя использовать контактный e-mail.

Обязательные поля отмечены звездочкой (*).

(Отображаемое имя должно иметь длину от 3 символов до 31 символа.)

Нажимая Отправить, Вы принимаете Условия использования developerWorks.

 


Вся введенная информация защищена.


static.content.url=http://www.ibm.com/developerworks/js/artrating/
SITE_ID=40
Zone=XML
ArticleID=362981
ArticleTitle=Введение в XSLT
publish-date=01122009